tjh.dev
1{ lib, stdenv, fetchurl, kernel }:
2
3let
4 version = "6.30.223.271";
5 hashes = {
6 i686-linux = "1kaqa2dw3nb8k23ffvx46g8jj3wdhz8xa6jp1v3wb35cjfr712sg";
7 x86_64-linux = "1gj485qqr190idilacpxwgqyw21il03zph2rddizgj7fbd6pfyaz";
8 };
9
10 arch = lib.optionalString (stdenv.hostPlatform.system == "x86_64-linux") "_64";
11 tarballVersion = lib.replaceStrings ["."] ["_"] version;
12 tarball = "hybrid-v35${arch}-nodebug-pcoem-${tarballVersion}.tar.gz";
13in
14stdenv.mkDerivation {
15 name = "broadcom-sta-${version}-${kernel.version}";
16
17 src = fetchurl {
18 url = "https://docs.broadcom.com/docs-and-downloads/docs/linux_sta/${tarball}";
19 sha256 = hashes.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
20 };
21
22 hardeningDisable = [ "pic" ];
23
24 nativeBuildInputs = kernel.moduleBuildDependencies;
25
26 patches = [
27 ./license.patch
28 ./linux-4.7.patch
29 # source: https://git.archlinux.org/svntogit/community.git/tree/trunk/004-linux48.patch?h=packages/broadcom-wl-dkms
30 ./linux-4.8.patch
31 # source: https://aur.archlinux.org/cgit/aur.git/tree/linux411.patch?h=broadcom-wl
32 ./linux-4.11.patch
33 # source: https://aur.archlinux.org/cgit/aur.git/tree/linux412.patch?h=broadcom-wl
34 ./linux-4.12.patch
35 ./linux-4.15.patch
36 ./linux-5.1.patch
37 # source: https://salsa.debian.org/Herrie82-guest/broadcom-sta/-/commit/247307926e5540ad574a17c062c8da76990d056f
38 ./linux-5.6.patch
39 # source: https://gist.github.com/joanbm/5c640ac074d27fd1d82c74a5b67a1290
40 ./linux-5.9.patch
41 # source: https://github.com/archlinux/svntogit-community/blob/33b4bd2b9e30679b03f5d7aa2741911d914dcf94/trunk/012-linux517.patch
42 ./linux-5.17.patch
43 # source: https://github.com/archlinux/svntogit-community/blob/2e1fd240f9ce06f500feeaa3e4a9675e65e6b967/trunk/013-linux518.patch
44 ./linux-5.18.patch
45 # source: https://gist.github.com/joanbm/207210d74637870c01ef5a3c262a597d
46 ./linux-6.0.patch
47 # source: https://gist.github.com/joanbm/94323ea99eff1e1d1c51241b5b651549
48 ./linux-6.1.patch
49 ./pedantic-fix.patch
50 ./null-pointer-fix.patch
51 ./gcc.patch
52 ];
53
54 makeFlags = [ "KBASE=${kernel.dev}/lib/modules/${kernel.modDirVersion}" ];
55
56 unpackPhase = ''
57 sourceRoot=broadcom-sta
58 mkdir "$sourceRoot"
59 tar xvf "$src" -C "$sourceRoot"
60 '';
61
62 installPhase = ''
63 binDir="$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
64 docDir="$out/share/doc/broadcom-sta/"
65 mkdir -p "$binDir" "$docDir"
66 cp wl.ko "$binDir"
67 cp lib/LICENSE.txt "$docDir"
68 '';
69
70 meta = {
71 description = "Kernel module driver for some Broadcom's wireless cards";
72 homepage = "http://www.broadcom.com/support/802.11/linux_sta.php";
73 license = lib.licenses.unfreeRedistributable;
74 maintainers = [ ];
75 platforms = lib.platforms.linux;
76 };
77}