tjh.dev
Clone of https://github.com/NixOS/nixpkgs.git (to stress-test knotserver)
1{ lib
2, maven
3, fetchFromGitHub
4, jre
5, makeWrapper
6}:
7maven.buildMavenPackage rec {
8 pname = "apgdiff";
9 version = "2.7.0";
10
11 src = fetchFromGitHub {
12 sparseCheckout = [ "src" ];
13 owner = "fordfrog";
14 repo = "apgdiff";
15 rev = "refs/tags/release_${version}";
16 hash = "sha256-2m+9QNwQV2tJwOabTXE2xjRB5gDrSwyL6zL2op+wmkM=";
17 };
18
19 # Fix wrong version string in --help
20 postPatch = ''
21 sed -i 's/VersionNumber=.*/VersionNumber=${version}/' \
22 src/main/resources/cz/startnet/utils/pgdiff/Resources.properties
23 '';
24
25 mvnHash = "sha256-zJQirS8sVqHKZsBukEOf7ox5IeiAVOP6wEHWb4CAyxc=";
26
27 nativeBuildInputs = [ makeWrapper ];
28
29 installPhase = ''
30 install -Dm644 target/apgdiff-${version}.jar $out/lib/apgdiff.jar
31
32 mkdir -p $out/bin
33 makeWrapper ${jre}/bin/java $out/bin/apgdiff \
34 --argv0 apgdiff \
35 --add-flags "-jar $out/lib/apgdiff.jar"
36 '';
37
38 meta = with lib; {
39 description = "Another PostgreSQL diff tool";
40 mainProgram = "apgdiff";
41 homepage = "https://apgdiff.com";
42 license = licenses.mit;
43 inherit (jre.meta) platforms;
44 maintainers = [ maintainers.misterio77 ];
45 };
46}