tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib
2, buildDunePackage, camlp5
3, ocaml
4, menhir, menhirLib
5, atdgen
6, stdlib-shims
7, re, perl, ncurses
8, ppxlib, ppx_deriving
9, ppxlib_0_15, ppx_deriving_0_15
10, coqPackages
11, version ? if lib.versionAtLeast ocaml.version "4.08" then "1.18.1"
12 else if lib.versionAtLeast ocaml.version "4.07" then "1.15.2" else "1.14.1"
13}:
14
15let p5 = camlp5; in
16let camlp5 = p5.override { legacy = true; }; in
17
18let fetched = coqPackages.metaFetch ({
19 release."1.19.2".sha256 = "sha256-7VTUbsFVoNT6srLwcAn5WNSsWC7cVUdphKRWBHHiH5M=";
20 release."1.18.1".sha256 = "sha256-zgBJefQDe3JyCGbC0wvMcx/9iMVbftBJ43NPogkNeHY=";
21 release."1.17.0".sha256 = "sha256-DTxE8CvYl0et20pxueydI+WzraI6UPHMNvxyp2gU/+w=";
22 release."1.16.5".sha256 = "sha256-tKX5/cVPoBeHiUe+qn7c5FIRYCwY0AAukN7vSd/Nz9A=";
23 release."1.15.2".sha256 = "sha256-XgopNP83POFbMNyl2D+gY1rmqGg03o++Ngv3zJfCn2s=";
24 release."1.15.0".sha256 = "sha256:1ngdc41sgyzyz3i3lkzjhnj66gza5h912virkh077dyv17ysb6ar";
25 release."1.14.1".sha256 = "sha256-BZPVL8ymjrE9kVGyf6bpc+GA2spS5JBpkUtZi04nPis=";
26 release."1.13.7".sha256 = "10fnwz30bsvj7ii1vg4l1li5pd7n0qqmwj18snkdr5j9gk0apc1r";
27 release."1.13.5".sha256 = "02a6r23mximrdvs6kgv6rp0r2dgk7zynbs99nn7lphw2c4189kka";
28 release."1.13.1".sha256 = "12a9nbdvg9gybpw63lx3nw5wnxfznpraprb0wj3l68v1w43xq044";
29 release."1.13.0".sha256 = "0dmzy058m1mkndv90byjaik6lzzfk3aaac7v84mpmkv6my23bygr";
30 release."1.12.0".sha256 = "1agisdnaq9wrw3r73xz14yrq3wx742i6j8i5icjagqk0ypmly2is";
31 release."1.11.4".sha256 = "1m0jk9swcs3jcrw5yyw5343v8mgax238cjb03s8gc4wipw1fn9f5";
32 releaseRev = v: "v${v}";
33 location = { domain = "github.com"; owner = "LPCIC"; repo = "elpi"; };
34 }) version;
35in
36buildDunePackage rec {
37 pname = "elpi";
38 inherit (fetched) version src;
39
40 patches = lib.optional (version == "1.16.5")
41 ./atd_2_10.patch;
42
43 minimalOCamlVersion = "4.04";
44 duneVersion = "3";
45
46 # atdgen is both a library and executable
47 nativeBuildInputs = [ perl ]
48 ++ [ (if lib.versionAtLeast version "1.15" || version == "dev" then menhir else camlp5) ]
49 ++ lib.optional (lib.versionAtLeast version "1.16" || version == "dev") atdgen;
50 buildInputs = [ ncurses ]
51 ++ lib.optional (lib.versionAtLeast version "1.16" || version == "dev") atdgen;
52
53 propagatedBuildInputs = [ re stdlib-shims ]
54 ++ (if lib.versionAtLeast version "1.15" || version == "dev"
55 then [ menhirLib ]
56 else [ camlp5 ]
57 )
58 ++ (if lib.versionAtLeast version "1.13" || version == "dev"
59 then [ ppxlib ppx_deriving ]
60 else [ ppxlib_0_15 ppx_deriving_0_15 ]
61 );
62
63 meta = with lib; {
64 description = "Embeddable λProlog Interpreter";
65 license = licenses.lgpl21Plus;
66 maintainers = [ maintainers.vbgl ];
67 homepage = "https://github.com/LPCIC/elpi";
68 };
69
70 postPatch = ''
71 substituteInPlace elpi_REPL.ml --replace "tput cols" "${ncurses}/bin/tput cols"
72 '';
73}