tjh.dev
1{ lib, stdenv, fetchFromGitHub, cmake, pkg-config, unzip
2, zlib
3, enableGtk2 ? false, gtk2
4, enableJPEG ? true, libjpeg
5, enablePNG ? true, libpng
6, enableTIFF ? true, libtiff
7, enableEXR ? (!stdenv.isDarwin), openexr, ilmbase
8, enableFfmpeg ? false, ffmpeg
9, enableGStreamer ? false, gst_all_1
10, enableEigen ? true, eigen
11, enableUnfree ? false
12, AVFoundation, Cocoa, QTKit, Accelerate
13}:
14
15let
16 opencvFlag = name: enabled: "-DWITH_${name}=${if enabled then "ON" else "OFF"}";
17
18in
19
20stdenv.mkDerivation rec {
21 pname = "opencv";
22 version = "2.4.13.7";
23
24 src = fetchFromGitHub {
25 owner = "opencv";
26 repo = "opencv";
27 rev = version;
28 sha256 = "062js7zhh4ixi2wk61wyi23qp9zsk5vw24iz2i5fab2hp97y5zq3";
29 };
30
31 patches =
32 [ # Don't include a copy of the CMake status output in the
33 # build. This causes a runtime dependency on GCC.
34 ./no-build-info.patch
35 ];
36
37 # This prevents cmake from using libraries in impure paths (which causes build failure on non NixOS)
38 postPatch = ''
39 sed -i '/Add these standard paths to the search paths for FIND_LIBRARY/,/^\s*$/{d}' CMakeLists.txt
40 '';
41
42 outputs = [ "out" "dev" ];
43
44 buildInputs =
45 [ zlib ]
46 ++ lib.optional enableGtk2 gtk2
47 ++ lib.optional enableJPEG libjpeg
48 ++ lib.optional enablePNG libpng
49 ++ lib.optional enableTIFF libtiff
50 ++ lib.optionals enableEXR [ openexr ilmbase ]
51 ++ lib.optional enableFfmpeg ffmpeg
52 ++ lib.optionals enableGStreamer (with gst_all_1; [ gstreamer gst-plugins-base ])
53 ++ lib.optional enableEigen eigen
54 ++ lib.optionals stdenv.isDarwin [ AVFoundation Cocoa QTKit Accelerate ]
55 ;
56
57 nativeBuildInputs = [ cmake pkg-config unzip ];
58
59 CXXFLAGS = lib.optionalString stdenv.cc.isClang "-std=c++14";
60
61 env.NIX_CFLAGS_COMPILE = lib.optionalString enableEXR "-I${ilmbase.dev}/include/OpenEXR";
62
63 cmakeFlags = [
64 (opencvFlag "TIFF" enableTIFF)
65 (opencvFlag "JPEG" enableJPEG)
66 (opencvFlag "PNG" enablePNG)
67 (opencvFlag "OPENEXR" enableEXR)
68 (opencvFlag "GSTREAMER" enableGStreamer)
69 ] ++ lib.optional (!enableUnfree) "-DBUILD_opencv_nonfree=OFF";
70
71 hardeningDisable = [ "bindnow" "relro" ];
72
73 # Fix pkg-config file that gets broken with multiple outputs
74 postFixup = ''
75 sed -i $dev/lib/pkgconfig/opencv.pc -e "s|includedir_old=.*|includedir_old=$dev/include/opencv|"
76 sed -i $dev/lib/pkgconfig/opencv.pc -e "s|includedir_new=.*|includedir_new=$dev/include|"
77 '';
78
79 meta = with lib; {
80 description = "Open Computer Vision Library with more than 500 algorithms";
81 homepage = "https://opencv.org/";
82 license = if enableUnfree then licenses.unfree else licenses.bsd3;
83 maintainers = [ ];
84 platforms = platforms.unix;
85 };
86}