tjh.dev
1{ stdenv, lib, fetchurl, fetchpatch, pkg-config, libtool
2, gtk2-x11, gtk3-x11 , gtkSupport ? null
3, libpulseaudio, gst_all_1, libvorbis, libcap, systemd
4, Carbon, CoreServices, AppKit
5, withAlsa ? stdenv.isLinux, alsa-lib }:
6
7stdenv.mkDerivation rec {
8 pname = "libcanberra";
9 version = "0.30";
10
11 src = fetchurl {
12 url = "http://0pointer.de/lennart/projects/libcanberra/${pname}-${version}.tar.xz";
13 sha256 = "0wps39h8rx2b00vyvkia5j40fkak3dpipp1kzilqla0cgvk73dn2";
14 };
15
16 outputs = [ "out" "dev" ];
17
18 strictDeps = true;
19 nativeBuildInputs = [ pkg-config ];
20 buildInputs = [
21 libpulseaudio libvorbis
22 libtool # in buildInputs rather than nativeBuildInputs since libltdl is used (not libtool itself)
23 ] ++ (with gst_all_1; [ gstreamer gst-plugins-base ])
24 ++ lib.optional (gtkSupport == "gtk2") gtk2-x11
25 ++ lib.optional (gtkSupport == "gtk3") gtk3-x11
26 ++ lib.optionals stdenv.isDarwin [ Carbon CoreServices AppKit ]
27 ++ lib.optionals stdenv.isLinux [ libcap systemd ]
28 ++ lib.optional withAlsa alsa-lib;
29
30 configureFlags = [ "--disable-oss" ]
31 ++ lib.optional stdenv.isLinux "--with-systemdsystemunitdir=${placeholder "out"}/lib/systemd/system";
32
33 patches = [
34 (fetchpatch {
35 name = "0001-gtk-Don-t-assume-all-GdkDisplays-are-GdkX11Displays-.patch";
36 url = "http://git.0pointer.net/libcanberra.git/patch/?id=c0620e432650e81062c1967cc669829dbd29b310";
37 sha256 = "0rc7zwn39yxzxp37qh329g7375r5ywcqcaak8ryd0dgvg8m5hcx9";
38 })
39 ] ++ lib.optionals stdenv.isDarwin [
40 (fetchpatch {
41 url = "https://github.com/macports/macports-ports/raw/5a7965dfea7727d1ceedee46c7b0ccee9cb23468/audio/libcanberra/files/patch-configure.diff";
42 sha256 = "sha256-pEJy1krciUEg5BFIS8FJ4BubjfS/nt9aqi6BLnS1+4M=";
43 extraPrefix = "";
44 })
45 (fetchpatch {
46 url = "https://github.com/macports/macports-ports/raw/5a7965dfea7727d1ceedee46c7b0ccee9cb23468/audio/libcanberra/files/dynamic_lookup-11.patch";
47 sha256 = "sha256-nUjha2pKh5VZl0ZZzcr9NTo1TVuMqF4OcLiztxW+ofQ=";
48 extraPrefix = "";
49 })
50 ];
51
52 postInstall = ''
53 for f in $out/lib/*.la; do
54 sed 's|-lltdl|-L${libtool.lib}/lib -lltdl|' -i $f
55 done
56 '';
57
58 passthru = lib.optionalAttrs (gtkSupport != null) {
59 gtkModule = if gtkSupport == "gtk2" then "/lib/gtk-2.0" else "/lib/gtk-3.0/";
60 };
61
62 meta = with lib; {
63 description = "Implementation of the XDG Sound Theme and Name Specifications";
64 mainProgram = "canberra-gtk-play";
65 longDescription = ''
66 libcanberra is an implementation of the XDG Sound Theme and Name
67 Specifications, for generating event sounds on free desktops
68 such as GNOME. It comes with several backends (ALSA,
69 PulseAudio, OSS, GStreamer, null) and is designed to be
70 portable.
71 '';
72 homepage = "http://0pointer.de/lennart/projects/libcanberra/";
73 license = licenses.lgpl2Plus;
74 maintainers = with maintainers; [ RossComputerGuy ];
75 platforms = platforms.unix;
76 };
77}