tjh.dev
1{ lib, stdenv, fetchurl, perl, ... }:
2
3let
4 version = "2.8.8";
5 folder = with builtins;
6 let parts = splitVersion version;
7 in concatStringsSep "." [ (elemAt parts 0) (elemAt parts 1) ];
8in stdenv.mkDerivation rec {
9 pname = "hyphen";
10 inherit version;
11
12 nativeBuildInputs = [ perl ];
13
14 src = fetchurl {
15 url =
16 "https://sourceforge.net/projects/hunspell/files/Hyphen/${folder}/${pname}-${version}.tar.gz";
17 sha256 = "01ap9pr6zzzbp4ky0vy7i1983fwyqy27pl0ld55s30fdxka3ciih";
18 };
19
20 # Do not install the en_US dictionary.
21 installPhase = ''
22 runHook preInstall
23 make install-libLTLIBRARIES
24 make install-binSCRIPTS
25 make install-includeHEADERS
26
27 # license
28 install -D -m644 COPYING "$out/share/licenses/${pname}/LICENSE"
29 runHook postInstall
30 '';
31
32 meta = with lib; {
33 description = "Text hyphenation library";
34 mainProgram = "substrings.pl";
35 homepage = "https://sourceforge.net/projects/hunspell/files/Hyphen/";
36 platforms = platforms.all;
37 license = with licenses; [ gpl2 lgpl21 mpl11 ];
38 maintainers = with maintainers; [ Br1ght0ne ];
39 };
40}