tjh.dev
1{ lib, stdenv, fetchFromGitHub, llvmPackages_16, ncurses, cmake, libxml2
2, symlinkJoin, breakpointHook, cudaPackages, enableCUDA ? false
3, libffi, libobjc, libpfm, Cocoa, Foundation
4}:
5
6let
7 luajitRev = "50936d784474747b4569d988767f1b5bab8bb6d0";
8 luajitBase = "LuaJIT-${luajitRev}";
9 luajitArchive = "${luajitBase}.tar.gz";
10 luajitSrc = fetchFromGitHub {
11 owner = "LuaJIT";
12 repo = "LuaJIT";
13 rev = luajitRev;
14 sha256 = "1g87pl014b5v6z2nnhiwn3wf405skawszfr5wdzyfbx00j3kgxd0";
15 };
16
17 llvmPackages = llvmPackages_16;
18 llvmMerged = symlinkJoin {
19 name = "llvmClangMerged";
20 paths = with llvmPackages; [
21 llvm.out
22 llvm.dev
23 llvm.lib
24 clang-unwrapped.out
25 clang-unwrapped.dev
26 clang-unwrapped.lib
27 ];
28 };
29
30 cuda = cudaPackages.cudatoolkit_11;
31
32 clangVersion = llvmPackages.clang-unwrapped.version;
33
34in stdenv.mkDerivation rec {
35 pname = "terra";
36 version = "1.1.0";
37
38 src = fetchFromGitHub {
39 owner = "terralang";
40 repo = "terra";
41 rev = "release-${version}";
42 sha256 = "0v9vpxcp9ybwnfljskqn41vjq7c0srdfv7qs890a6480pnk4kavd";
43 };
44
45 nativeBuildInputs = [ cmake ];
46 buildInputs = [ llvmMerged ncurses libffi libxml2 ]
47 ++ lib.optionals enableCUDA [ cuda ]
48 ++ lib.optional (!stdenv.isDarwin) libpfm
49 ++ lib.optionals stdenv.isDarwin [ libobjc Cocoa Foundation ];
50
51 cmakeFlags = let
52 resourceDir = "${llvmMerged}/lib/clang/" + (
53 if lib.versionOlder clangVersion "16"
54 then
55 clangVersion
56 else
57 lib.versions.major clangVersion
58 );
59 in [
60 "-DHAS_TERRA_VERSION=0"
61 "-DTERRA_VERSION=${version}"
62 "-DTERRA_LUA=luajit"
63 "-DTERRA_SKIP_LUA_DOWNLOAD=ON"
64 "-DCLANG_RESOURCE_DIR=${resourceDir}"
65 ] ++ lib.optional enableCUDA "-DTERRA_ENABLE_CUDA=ON";
66
67 doCheck = true;
68 hardeningDisable = [ "fortify" ];
69 outputs = [ "bin" "dev" "out" "static" ];
70
71 patches = [ ./nix-cflags.patch ];
72
73 postPatch = ''
74 substituteInPlace src/terralib.lua \
75 --subst-var-by NIX_LIBC_INCLUDE ${lib.getDev stdenv.cc.libc}/include
76 '';
77
78 preConfigure = ''
79 mkdir -p build
80 ln -s ${luajitSrc} build/${luajitBase}
81 tar --mode="a+rwX" -chzf build/${luajitArchive} -C build ${luajitBase}
82 rm build/${luajitBase}
83 '';
84
85 installPhase = ''
86 install -Dm755 -t $bin/bin bin/terra
87 install -Dm755 -t $out/lib lib/terra${stdenv.hostPlatform.extensions.sharedLibrary}
88 install -Dm644 -t $static/lib lib/libterra_s.a
89
90 mkdir -pv $dev/include
91 cp -rv include/terra $dev/include
92 '';
93
94 meta = with lib; {
95 description = "Low-level counterpart to Lua";
96 homepage = "https://terralang.org/";
97 platforms = platforms.all;
98 maintainers = with maintainers; [ jb55 seylerius thoughtpolice elliottslaughter ];
99 license = licenses.mit;
100 # never built on aarch64-darwin since first introduction in nixpkgs
101 # Linux Aarch64 broken above LLVM11
102 # https://github.com/terralang/terra/issues/597
103 broken = stdenv.isAarch64;
104 };
105}