tjh.dev
1{ useNixpkgsEngine ? false, callPackage, fetchzip, fetchFromGitHub, dart, lib, stdenv }@args:
2let
3 mkCustomFlutter = args: callPackage ./flutter.nix args;
4 wrapFlutter = flutter: callPackage ./wrapper.nix { inherit flutter; };
5 getPatches = dir:
6 let files = builtins.attrNames (builtins.readDir dir);
7 in if (builtins.pathExists dir) then map (f: dir + ("/" + f)) files else [ ];
8 mkFlutter =
9 { version
10 , engineVersion
11 , engineSwiftShaderHash
12 , engineSwiftShaderRev
13 , engineHashes
14 , enginePatches
15 , dartVersion
16 , flutterHash
17 , dartHash
18 , patches
19 , pubspecLock
20 , artifactHashes
21 , channel
22 }@fargs:
23 let
24 args = {
25 inherit version engineVersion engineSwiftShaderRev engineSwiftShaderHash engineHashes enginePatches patches pubspecLock artifactHashes useNixpkgsEngine channel;
26
27 dart = dart.override {
28 version = dartVersion;
29 sources = {
30 "${dartVersion}-x86_64-linux" = fetchzip {
31 url = "https://storage.googleapis.com/dart-archive/channels/${channel}/release/${dartVersion}/sdk/dartsdk-linux-x64-release.zip";
32 sha256 = dartHash.x86_64-linux;
33 };
34 "${dartVersion}-aarch64-linux" = fetchzip {
35 url = "https://storage.googleapis.com/dart-archive/channels/${channel}/release/${dartVersion}/sdk/dartsdk-linux-arm64-release.zip";
36 sha256 = dartHash.aarch64-linux;
37 };
38 "${dartVersion}-x86_64-darwin" = fetchzip {
39 url = "https://storage.googleapis.com/dart-archive/channels/${channel}/release/${dartVersion}/sdk/dartsdk-macos-x64-release.zip";
40 sha256 = dartHash.x86_64-darwin;
41 };
42 "${dartVersion}-aarch64-darwin" = fetchzip {
43 url = "https://storage.googleapis.com/dart-archive/channels/${channel}/release/${dartVersion}/sdk/dartsdk-macos-arm64-release.zip";
44 sha256 = dartHash.aarch64-darwin;
45 };
46 };
47 };
48 src = fetchFromGitHub {
49 owner = "flutter";
50 repo = "flutter";
51 rev = version;
52 hash = flutterHash;
53 };
54 };
55 in
56 (mkCustomFlutter args).overrideAttrs (prev: next: {
57 passthru = next.passthru // rec {
58 inherit wrapFlutter mkCustomFlutter mkFlutter;
59 buildFlutterApplication = callPackage ../../../build-support/flutter { flutter = wrapFlutter (mkCustomFlutter args); };
60 };
61 });
62
63 flutterVersions = lib.mapAttrs'
64 (version: _:
65 let
66 versionDir = ./versions + "/${version}";
67 data = lib.importJSON (versionDir + "/data.json");
68 in
69 lib.nameValuePair "v${version}" (wrapFlutter (mkFlutter ({
70 patches = (getPatches ./patches) ++ (getPatches (versionDir + "/patches"));
71 enginePatches = (getPatches ./engine/patches) ++ (getPatches (versionDir + "/engine/patches"));
72 } // data))))
73 (builtins.readDir ./versions);
74
75 stableFlutterVersions = lib.attrsets.filterAttrs (_: v: v.channel == "stable") flutterVersions;
76 betaFlutterVersions = lib.attrsets.filterAttrs (_: v: v.channel == "beta") flutterVersions;
77in
78flutterVersions // {
79 beta = flutterVersions.${lib.last (lib.naturalSort (builtins.attrNames betaFlutterVersions))};
80 stable = flutterVersions.${lib.last (lib.naturalSort (builtins.attrNames stableFlutterVersions))};
81 inherit wrapFlutter mkFlutter;
82}