tjh.dev
1{
2 nixpkgs,
3 officialRelease,
4 pkgs ? import nixpkgs.outPath { },
5 nix ? pkgs.nix,
6 lib-tests ? import ../../lib/tests/release.nix {
7 pkgs = import nixpkgs.outPath {
8 config = {
9 permittedInsecurePackages = [ "nix-2.3.18" ];
10 };
11 };
12 },
13}:
14
15pkgs.releaseTools.sourceTarball {
16 name = "nixpkgs-tarball";
17 src = nixpkgs;
18
19 inherit officialRelease;
20 version = pkgs.lib.fileContents ../../.version;
21 versionSuffix = "pre${
22 if nixpkgs ? lastModified then
23 builtins.substring 0 8 (nixpkgs.lastModifiedDate or nixpkgs.lastModified)
24 else
25 toString (nixpkgs.revCount or 0)
26 }.${nixpkgs.shortRev or "dirty"}";
27
28 buildInputs = with pkgs; [
29 nix.out
30 jq
31 lib-tests
32 brotli
33 ];
34
35 configurePhase = ''
36 eval "$preConfigure"
37 releaseName=nixpkgs-$VERSION$VERSION_SUFFIX
38 echo -n $VERSION_SUFFIX > .version-suffix
39 echo -n ${nixpkgs.rev or nixpkgs.shortRev or "dirty"} > .git-revision
40 echo "release name is $releaseName"
41 echo "git-revision is $(cat .git-revision)"
42 '';
43
44 dontUnpack = true;
45
46 dontBuild = false;
47
48 doCheck = true;
49
50 checkPhase = ''
51 echo "generating packages.json"
52
53 (
54 echo -n '{"version":2,"packages":'
55 NIX_STATE_DIR=$TMPDIR NIX_PATH= nix-env -f $src -qa --meta --json --show-trace --arg config 'import ${./packages-config.nix}'
56 echo -n '}'
57 ) | sed "s|$src/||g" | jq -c > packages.json
58
59 # Arbitrary number. The index has ~115k packages as of April 2024.
60 if [ $(jq -r '.packages | length' < packages.json) -lt 100000 ]; then
61 echo "ERROR: not enough packages in the search index, bailing out!"
62 exit 1
63 fi
64
65 packages=$out/packages.json.br
66
67 mkdir -p $out/nix-support
68 brotli -9 < packages.json > $packages
69 echo "file json-br $packages" >> $out/nix-support/hydra-build-products
70 '';
71
72 # --hard-dereference: reproducibility for src if auto-optimise-store = true
73 # Some context: https://github.com/NixOS/infra/issues/438
74 distPhase = ''
75 mkdir -p $out/tarballs
76 XZ_OPT="-T0" tar \
77 --create \
78 --xz \
79 --file=$out/tarballs/$releaseName.tar.xz \
80 --absolute-names \
81 --transform="s|^$src|$releaseName|g" \
82 --transform="s|^$(pwd)|$releaseName|g" \
83 --owner=0 \
84 --group=0 \
85 --numeric-owner \
86 --format=gnu \
87 --sort=name \
88 --mtime="@$SOURCE_DATE_EPOCH" \
89 --mode=ug+w \
90 --hard-dereference \
91 $src $(pwd)/{.version-suffix,.git-revision}
92 '';
93}