pkgs/tools/misc/parallel/wrapper.nix at devShellTools-shell · tjh.dev/nixpkgs

tjh.dev / nixpkgs

Clone of https://github.com/NixOS/nixpkgs.git (to stress-test knotserver)

nixpkgs / pkgs / tools / misc / parallel / wrapper.nix

at devShellTools-shell 37 lines 796 B view raw

 1{
 2  lib,
 3  symlinkJoin,
 4  makeWrapper,
 5  parallel,
 6  perlPackages,
 7  extraPerlPackages ? with perlPackages; [
 8    DBI
 9    DBDPg
10    DBDSQLite
11    DBDCSV
12    TextCSV
13  ],
14  willCite ? false,
15}:
16
17symlinkJoin {
18  name = "parallel-full-${parallel.version}";
19  inherit (parallel)
20    pname
21    version
22    meta
23    outputs
24    ;
25  nativeBuildInputs = [ makeWrapper ];
26  paths = [ parallel ];
27  postBuild = ''
28    ${lib.concatMapStringsSep "\n" (
29      output: "ln -s --no-target-directory ${parallel.${output}} \$${output}"
30    ) (lib.remove "out" parallel.outputs)}
31
32    rm $out/bin/parallel
33    makeWrapper ${parallel}/bin/parallel $out/bin/parallel \
34      --set PERL5LIB "${perlPackages.makeFullPerlPath extraPerlPackages}" \
35      ${lib.optionalString willCite "--add-flags --will-cite"}
36  '';
37}