tjh.dev
1{
2 lib,
3 stdenv,
4 fetchurl,
5 autoPatchelfHook,
6 addDriverRunpath,
7 makeWrapper,
8 ocl-icd,
9 vulkan-loader,
10}:
11
12stdenv.mkDerivation rec {
13 pname = "geekbench";
14 version = "4.4.4";
15
16 src = fetchurl {
17 url = "https://cdn.geekbench.com/Geekbench-${version}-Linux.tar.gz";
18 sha256 = "sha256-KVsBE0ueWewmoVY/vzxX2sKhRTzityPNR+wmTwZBWiI=";
19 };
20
21 dontConfigure = true;
22 dontBuild = true;
23
24 nativeBuildInputs = [
25 autoPatchelfHook
26 makeWrapper
27 ];
28 buildInputs = [ stdenv.cc.cc ];
29
30 installPhase = ''
31 runHook preInstall
32
33 mkdir -p $out/bin
34 cp -r geekbench.plar geekbench4 geekbench_x86_64 $out/bin
35
36 for f in geekbench4 geekbench_x86_64 ; do
37 wrapProgram $out/bin/$f \
38 --prefix LD_LIBRARY_PATH : "${
39 lib.makeLibraryPath [
40 addDriverRunpath.driverLink
41 ocl-icd
42 vulkan-loader
43 ]
44 }"
45 done
46
47 runHook postInstall
48 '';
49
50 meta = with lib; {
51 description = "Cross-platform benchmark";
52 homepage = "https://geekbench.com/";
53 sourceProvenance = with sourceTypes; [ binaryNativeCode ];
54 license = licenses.unfree;
55 maintainers = [ maintainers.michalrus ];
56 platforms = [ "x86_64-linux" ];
57 mainProgram = "geekbench4";
58 };
59}