tjh.dev
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 kernel,
6 bc,
7 nukeReferences,
8}:
9
10stdenv.mkDerivation (finalAttrs: {
11 pname = "rtl8852au";
12 version = "${kernel.version}-unstable-2024-05-06";
13
14 src = fetchFromGitHub {
15 owner = "lwfinger";
16 repo = "rtl8852au";
17 rev = "865ab0fa91471d595c283d2f3db323f7f15455f5";
18 hash = "sha256-c2dpnZS6a0waL1khB9ZEglTwJIBsyRebTMig1B4A0xU=";
19 };
20
21 nativeBuildInputs = [
22 bc
23 nukeReferences
24 ]
25 ++ kernel.moduleBuildDependencies;
26 hardeningDisable = [
27 "pic"
28 "format"
29 ];
30
31 patches = [
32 # https://github.com/lwfinger/rtl8852au/pull/115
33 ./fix-build-for-kernels-6.13-6.14.patch
34 ];
35
36 postPatch = ''
37 substituteInPlace ./Makefile \
38 --replace-fail /sbin/depmod \# \
39 --replace-fail '$(MODDESTDIR)' "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/" \
40 --replace-fail '/usr/lib/systemd/system-sleep' "$out/usr/lib/systemd/system-sleep"
41 substituteInPlace ./platform/i386_pc.mk \
42 --replace-fail /lib/modules "${kernel.dev}/lib/modules"
43 '';
44
45 makeFlags = [
46 "ARCH=${stdenv.hostPlatform.linuxArch}"
47 ("CONFIG_PLATFORM_I386_PC=" + (if stdenv.hostPlatform.isx86 then "y" else "n"))
48 ("CONFIG_PLATFORM_ARM_RPI=" + (if stdenv.hostPlatform.isAarch then "y" else "n"))
49 ]
50 ++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
51 "CROSS_COMPILE=${stdenv.cc.targetPrefix}"
52 ];
53
54 preInstall = ''
55 mkdir -p "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
56 mkdir -p "$out/usr/lib/systemd/system-sleep"
57 '';
58
59 postInstall = ''
60 nuke-refs $out/lib/modules/*/kernel/net/wireless/*.ko
61 '';
62
63 # GCC 14 makes this an error by default
64 env.NIX_CFLAGS_COMPILE = "-Wno-designated-init";
65
66 enableParallelBuilding = true;
67
68 meta = with lib; {
69 description = "Driver for Realtek 802.11ac, rtl8852au, provides the 8852au mod";
70 homepage = "https://github.com/lwfinger/rtl8852au";
71 license = licenses.gpl2Only;
72 platforms = [ "x86_64-linux" ];
73 # FIX: error: invalid initializer
74 broken = kernel.kernelOlder "6" && kernel.isHardened;
75 maintainers = with maintainers; [ lonyelon ];
76 };
77})