tjh.dev
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 kernel,
6 bc,
7 nukeReferences,
8}:
9
10stdenv.mkDerivation {
11 pname = "rtl8812au";
12 version = "${kernel.version}-unstable-2024-06-13";
13
14 src = fetchFromGitHub {
15 owner = "morrownr";
16 repo = "8812au-20210820";
17 rev = "c0efee9cd121d9f0c815d9771475f76339a8f7d3";
18 hash = "sha256-ZS0iUb77XnXR5BUMeQ1EDuly7hStRt430ECueFW4v4w=";
19 };
20
21 nativeBuildInputs = [
22 bc
23 nukeReferences
24 ]
25 ++ kernel.moduleBuildDependencies;
26 hardeningDisable = [
27 "pic"
28 "format"
29 ];
30
31 prePatch = ''
32 substituteInPlace ./Makefile \
33 --replace /lib/modules/ "${kernel.dev}/lib/modules/" \
34 --replace /sbin/depmod \# \
35 --replace '$(MODDESTDIR)' "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
36 '';
37
38 makeFlags = [
39 "ARCH=${stdenv.hostPlatform.linuxArch}"
40 ("CONFIG_PLATFORM_I386_PC=" + (if stdenv.hostPlatform.isx86 then "y" else "n"))
41 ("CONFIG_PLATFORM_ARM_RPI=" + (if stdenv.hostPlatform.isAarch then "y" else "n"))
42 ]
43 ++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
44 "CROSS_COMPILE=${stdenv.cc.targetPrefix}"
45 ];
46
47 preInstall = ''
48 mkdir -p "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
49 '';
50
51 postInstall = ''
52 nuke-refs $out/lib/modules/*/kernel/net/wireless/*.ko
53 '';
54
55 enableParallelBuilding = true;
56
57 meta = with lib; {
58 description = "Driver for Realtek 802.11ac, rtl8812au, provides the 8812au mod";
59 homepage = "https://github.com/morrownr/8812au-20210820";
60 license = licenses.gpl2Only;
61 platforms = platforms.linux;
62 maintainers = with maintainers; [ moni ];
63 };
64}