tjh.dev
1{
2 lib,
3 stdenv,
4 fetchurl,
5 ocaml,
6 findlib,
7 ocamlbuild,
8 ocamlmod,
9 ocamlify,
10}:
11
12stdenv.mkDerivation {
13 version = "0.4.11";
14 pname = "ocaml-oasis";
15
16 src = fetchurl {
17 url = "https://download.ocamlcore.org/oasis/oasis/0.4.11/oasis-0.4.11.tar.gz";
18 hash = "sha256-GLc97vTtbpqDM38ks7vi3tZSaLP/cwn8wA0l5X4dwS4=";
19 };
20
21 createFindlibDestdir = true;
22
23 strictDeps = true;
24
25 nativeBuildInputs = [
26 ocaml
27 findlib
28 ocamlbuild
29 ocamlmod
30 ocamlify
31 ];
32
33 buildInputs = [ ocamlbuild ];
34
35 configurePhase = ''
36 runHook preConfigure
37 ocaml setup.ml -configure --prefix $out
38 runHook postConfigure
39 '';
40 buildPhase = ''
41 runHook preBuild
42 ocaml setup.ml -build
43 runHook postBuild
44 '';
45 installPhase = ''
46 runHook preInstall
47 ocaml setup.ml -install
48 runHook postInstall
49 '';
50
51 meta = with lib; {
52 description = "Configure, build and install system for OCaml projects";
53 homepage = "https://github.com/ocaml/oasis";
54 license = licenses.lgpl21;
55 maintainers = with maintainers; [
56 vbgl
57 maggesi
58 ];
59 mainProgram = "oasis";
60 inherit (ocaml.meta) platforms;
61 };
62}