tjh.dev
1{
2 lib,
3 buildGoModule,
4 fetchFromGitHub,
5 installShellFiles,
6}:
7
8buildGoModule rec {
9 pname = "kustomize_4";
10 version = "4.5.7";
11
12 src = fetchFromGitHub {
13 owner = "kubernetes-sigs";
14 repo = "kustomize";
15 rev = "kustomize/v${version}";
16 hash = "sha256-AHDUwXcYkI04nOBY8jScf+OE6k9Z5OqzhtWExK1rrKg=";
17 };
18
19 # rev is the commit of the tag, mainly for kustomize version command output
20 rev = "56d82a8378dfc8dc3b3b1085e5a6e67b82966bd7";
21 ldflags =
22 let
23 t = "sigs.k8s.io/kustomize/api/provenance";
24 in
25 [
26 "-s"
27 "-X ${t}.version=${version}"
28 "-X ${t}.gitCommit=${rev}"
29 ];
30
31 # avoid finding test and development commands
32 modRoot = "kustomize";
33 proxyVendor = true;
34 vendorHash = "sha256-9+k0Me5alZDNC27Mx0Q6vp0B2SEa+Qy0FoLSr/Rahkc=";
35
36 nativeBuildInputs = [ installShellFiles ];
37
38 postInstall = ''
39 installShellCompletion --cmd kustomize \
40 --bash <($out/bin/kustomize completion bash) \
41 --fish <($out/bin/kustomize completion fish) \
42 --zsh <($out/bin/kustomize completion zsh)
43 '';
44
45 meta = with lib; {
46 description = "Customization of kubernetes YAML configurations";
47 mainProgram = "kustomize";
48 longDescription = ''
49 kustomize lets you customize raw, template-free YAML files for
50 multiple purposes, leaving the original YAML untouched and usable
51 as is.
52 '';
53 homepage = "https://github.com/kubernetes-sigs/kustomize";
54 license = licenses.asl20;
55 maintainers = with maintainers; [
56 carlosdagos
57 vdemeester
58 periklis
59 zaninime
60 Chili-Man
61 saschagrunert
62 ];
63 };
64}