tjh.dev
1{
2 lib,
3 stdenv,
4 fetchurl,
5 fetchpatch,
6 libtool,
7 autoconf,
8 automake,
9 gmp,
10 mpfr,
11 libffi,
12 makeWrapper,
13 noUnicode ? false,
14 gcc,
15 threadSupport ? false,
16 useBoehmgc ? true,
17 boehmgc,
18}:
19
20stdenv.mkDerivation rec {
21 pname = "ecl";
22 version = "16.1.2";
23
24 src = fetchurl {
25 url = "https://common-lisp.net/project/ecl/static/files/release/ecl-${version}.tgz";
26 sha256 = "sha256-LUgrGgpPvV2IFDRRcDInnYCMtkBeIt2R721zNTRGS5k=";
27 };
28
29 nativeBuildInputs = [
30 autoconf
31 automake
32 makeWrapper
33 libtool
34 ];
35 propagatedBuildInputs = [
36 libffi
37 gmp
38 mpfr
39 gcc
40 ]
41 ++ lib.optionals useBoehmgc [
42 # replaces ecl's own gc which other packages can depend on, thus propagated
43 boehmgc
44 ];
45
46 configureFlags = [
47 (if threadSupport then "--enable-threads" else "--disable-threads")
48 "--with-gmp-incdir=${lib.getDev gmp}/include"
49 "--with-gmp-libdir=${lib.getLib gmp}/lib"
50 # -incdir, -libdir doesn't seem to be supported for libffi
51 "--with-libffi-prefix=${lib.getDev libffi}"
52 ]
53 ++ lib.optional (!noUnicode) "--enable-unicode";
54
55 patches = [
56 (fetchpatch {
57 # Avoid infinite loop, see https://gitlab.com/embeddable-common-lisp/ecl/issues/43 (fixed upstream)
58 name = "avoid-infinite-loop.patch";
59 url = "https://gitlab.com/embeddable-common-lisp/ecl/commit/caba1989f40ef917e7486f41b9cd5c7e3c5c2d79.patch";
60 sha256 = "07vw91psbc9gdn8grql46ra8lq3bgkzg5v480chnbryna4sv6lbb";
61 })
62 (fetchpatch {
63 # Fix getcwd with long pathnames
64 # Rebased version of
65 # https://gitlab.com/embeddable-common-lisp/ecl/commit/ac5f011f57a85a38627af154bc3ee7580e7fecd4.patch
66 name = "getcwd.patch";
67 url = "https://raw.githubusercontent.com/sagemath/sage/07d6c37d18811e2b377a9689790a7c5e24da16ba/build/pkgs/ecl/patches/16.1.2-getcwd.patch";
68 sha256 = "1fbi8gn7rv8nqff5mpaijsrch3k3z7qc5cn4h1vl8qrr8xwqlqhb";
69 })
70 ./ecl-1.16.2-libffi-3.3-abi.patch
71 ];
72
73 hardeningDisable = [ "format" ];
74
75 postInstall = ''
76 sed -e 's/@[-a-zA-Z_]*@//g' -i $out/bin/ecl-config
77 wrapProgram "$out/bin/ecl" \
78 --prefix PATH ':' "${
79 lib.makeBinPath [
80 gcc # for the C compiler
81 gcc.bintools.bintools # for ar
82 ]
83 }" \
84 ''
85 # ecl 16.1.2 is too old to have -libdir for libffi and boehmgc, so we need to
86 # use NIX_LDFLAGS_BEFORE to make gcc find these particular libraries.
87 # Since it is missing even the prefix flag for boehmgc we also need to inject
88 # the correct -I flag via NIX_CFLAGS_COMPILE. Since we have access to it, we
89 # create the variables with suffixSalt (which seems to be necessary for
90 # NIX_CFLAGS_COMPILE even).
91 + lib.optionalString useBoehmgc ''
92 --prefix NIX_CFLAGS_COMPILE_${gcc.suffixSalt} ' ' "-I${lib.getDev boehmgc}/include" \
93 --prefix NIX_LDFLAGS_BEFORE_${gcc.bintools.suffixSalt} ' ' "-L${lib.getLib boehmgc}/lib" \
94 ''
95 + ''
96 --prefix NIX_LDFLAGS_BEFORE_${gcc.bintools.suffixSalt} ' ' "-L${lib.getLib libffi}/lib"
97 '';
98
99 meta = with lib; {
100 description = "Lisp implementation aiming to be small, fast and easy to embed";
101 license = licenses.mit;
102 teams = [ lib.teams.lisp ];
103 platforms = platforms.unix;
104 # never built on aarch64-darwin since first introduction in nixpkgs
105 broken = stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64;
106 };
107}