tjh.dev
1{
2 stdenv,
3 lib,
4 fetchFromGitLab,
5 gettext,
6 meson,
7 ninja,
8 pkg-config,
9 wrapGAppsHook3,
10 thunar,
11 exo,
12 libxfce4ui,
13 libxfce4util,
14 gtk3,
15 glib,
16 subversion,
17 apr,
18 aprutil,
19 withSubversion ? false,
20 gitUpdater,
21}:
22
23stdenv.mkDerivation (finalAttrs: {
24 pname = "thunar-vcs-plugin";
25 version = "0.4.0";
26
27 src = fetchFromGitLab {
28 domain = "gitlab.xfce.org";
29 owner = "thunar-plugins";
30 repo = "thunar-vcs-plugin";
31 tag = "thunar-vcs-plugin-${finalAttrs.version}";
32 hash = "sha256-VuTTao46/3JNzCHv7phCC8DCy9rjlEcMuGmGiIOSsMM=";
33 };
34
35 strictDeps = true;
36
37 nativeBuildInputs = [
38 gettext
39 meson
40 ninja
41 pkg-config
42 wrapGAppsHook3
43 ];
44
45 buildInputs = [
46 thunar
47 exo
48 libxfce4ui
49 libxfce4util
50 gtk3
51 glib
52 ]
53 ++ lib.optionals withSubversion [
54 apr
55 aprutil
56 subversion
57 ];
58
59 mesonFlags = [
60 (lib.mesonEnable "svn" withSubversion)
61 ];
62
63 passthru.updateScript = gitUpdater { rev-prefix = "thunar-vcs-plugin-"; };
64
65 meta = {
66 description = "Thunar plugin providing support for Subversion and Git";
67 homepage = "https://gitlab.xfce.org/thunar-plugins/thunar-vcs-plugin";
68 license = lib.licenses.lgpl2Only;
69 maintainers = with lib.maintainers; [ lordmzte ];
70 teams = [ lib.teams.xfce ];
71 platforms = lib.platforms.linux;
72 };
73})