tjh.dev
1{
2 stdenv,
3 lib,
4 fetchFromGitLab,
5 glib,
6 meson,
7 ninja,
8 pkg-config,
9 wrapGAppsHook3,
10 gspell,
11 gtk3,
12 gtksourceview4,
13 libxfce4ui,
14 xfconf,
15 enablePolkit ? true,
16 polkit,
17 gitUpdater,
18}:
19
20stdenv.mkDerivation (finalAttrs: {
21 pname = "mousepad";
22 version = "0.6.5";
23
24 src = fetchFromGitLab {
25 domain = "gitlab.xfce.org";
26 owner = "apps";
27 repo = "mousepad";
28 tag = "mousepad-${finalAttrs.version}";
29 hash = "sha256-5ywpQY4KUnjFCLSAXQo3huzZf94YHK9SLmkkNtfx4Ho=";
30 };
31
32 strictDeps = true;
33
34 nativeBuildInputs = [
35 glib # glib-compile-schemas
36 meson
37 ninja
38 pkg-config
39 wrapGAppsHook3
40 ];
41
42 buildInputs = [
43 glib
44 gspell
45 gtk3
46 gtksourceview4
47 libxfce4ui # for shortcut plugin
48 xfconf # required by libxfce4kbd-private-3
49 ]
50 ++ lib.optionals enablePolkit [
51 polkit
52 ];
53
54 # Use the GSettings keyfile backend rather than the default
55 mesonFlags = [ "-Dkeyfile-settings=true" ];
56
57 passthru.updateScript = gitUpdater { rev-prefix = "mousepad-"; };
58
59 meta = {
60 description = "Simple text editor for Xfce";
61 homepage = "https://gitlab.xfce.org/apps/mousepad";
62 license = lib.licenses.gpl2Plus;
63 mainProgram = "mousepad";
64 teams = [ lib.teams.xfce ];
65 platforms = lib.platforms.linux;
66 };
67})