tjh.dev
1{
2 pkgs,
3 makeScope,
4 kdePackages,
5}:
6
7let
8 packages =
9 self: with self; {
10
11 # For compiling information, see:
12 # - https://github.com/lxqt/lxqt/wiki/Building-from-source
13
14 ### BASE
15 libqtxdg = callPackage ./libqtxdg { };
16 lxqt-build-tools = callPackage ./lxqt-build-tools { };
17 libsysstat = callPackage ./libsysstat { };
18 liblxqt = callPackage ./liblxqt { };
19 qtxdg-tools = callPackage ./qtxdg-tools { };
20 libdbusmenu-lxqt = callPackage ./libdbusmenu-lxqt { };
21
22 ### CORE 1
23 libfm-qt = callPackage ./libfm-qt { };
24 lxqt-about = callPackage ./lxqt-about { };
25 lxqt-admin = callPackage ./lxqt-admin { };
26 lxqt-config = callPackage ./lxqt-config { };
27 lxqt-globalkeys = callPackage ./lxqt-globalkeys { };
28 lxqt-menu-data = callPackage ./lxqt-menu-data { };
29 lxqt-notificationd = callPackage ./lxqt-notificationd { };
30 lxqt-openssh-askpass = callPackage ./lxqt-openssh-askpass { };
31 lxqt-policykit = callPackage ./lxqt-policykit { };
32 lxqt-powermanagement = callPackage ./lxqt-powermanagement { };
33 lxqt-qtplugin = callPackage ./lxqt-qtplugin { };
34 lxqt-session = callPackage ./lxqt-session { };
35 lxqt-sudo = callPackage ./lxqt-sudo { };
36 lxqt-themes = callPackage ./lxqt-themes { };
37 lxqt-wayland-session = callPackage ./lxqt-wayland-session { };
38 pavucontrol-qt = callPackage ./pavucontrol-qt { };
39 qtermwidget = callPackage ./qtermwidget { };
40
41 ### CORE 2
42 lxqt-panel = callPackage ./lxqt-panel { };
43 lxqt-runner = callPackage ./lxqt-runner { };
44 pcmanfm-qt = callPackage ./pcmanfm-qt { };
45
46 ### OPTIONAL
47 qterminal = callPackage ./qterminal { };
48 compton-conf = callPackage ./compton-conf {
49 lxqt-build-tools = lxqt-build-tools_0_13;
50 inherit (pkgs.libsForQt5) qtbase qttools qtx11extras;
51 };
52 obconf-qt = callPackage ./obconf-qt { };
53 lximage-qt = callPackage ./lximage-qt { };
54 qps = callPackage ./qps { };
55 screengrab = callPackage ./screengrab { };
56 qlipper = callPackage ./qlipper {
57 inherit (pkgs.libsForQt5) qtbase qttools;
58 };
59 lxqt-archiver = callPackage ./lxqt-archiver { };
60 xdg-desktop-portal-lxqt = callPackage ./xdg-desktop-portal-lxqt { };
61
62 ### COMPATIBILITY
63 lxqt-build-tools_0_13 = callPackage ./lxqt-build-tools {
64 version = "0.13.0";
65 inherit (pkgs.libsForQt5) qtbase;
66 };
67 libqtxdg_3_12 = callPackage ./libqtxdg {
68 version = "3.12.0";
69 lxqt-build-tools = lxqt-build-tools_0_13;
70 inherit (pkgs.libsForQt5) qtbase qtsvg;
71 };
72 libfm-qt_1_4 = callPackage ./libfm-qt {
73 version = "1.4.0";
74 lxqt-build-tools = lxqt-build-tools_0_13;
75 inherit (pkgs.libsForQt5) qttools qtx11extras;
76 };
77 lxqt-qtplugin_1_4 = callPackage ./lxqt-qtplugin {
78 version = "1.4.1";
79 lxqt-build-tools = lxqt-build-tools_0_13;
80 libqtxdg = libqtxdg_3_12;
81 libfm-qt = libfm-qt_1_4;
82 inherit (pkgs.libsForQt5)
83 qtbase
84 qtsvg
85 qttools
86 libdbusmenu
87 ;
88 };
89 qtermwidget_1_4 = callPackage ./qtermwidget {
90 version = "1.4.0";
91 lxqt-build-tools = lxqt-build-tools_0_13;
92 inherit (pkgs.libsForQt5) qtbase qttools;
93 };
94
95 preRequisitePackages = [
96 kdePackages.kwindowsystem # provides some QT plugins needed by lxqt-panel
97 kdePackages.libkscreen # provides plugins for screen management software
98 pkgs.libfm
99 pkgs.libfm-extra
100 pkgs.menu-cache
101 pkgs.openbox # default window manager
102 kdePackages.qtsvg # provides QT plugins for svg icons
103 ];
104
105 corePackages = [
106 ### BASE
107 libqtxdg
108 libsysstat
109 liblxqt
110 qtxdg-tools
111 libdbusmenu-lxqt
112
113 ### CORE 1
114 libfm-qt
115 lxqt-about
116 lxqt-admin
117 lxqt-config
118 lxqt-globalkeys
119 lxqt-menu-data
120 lxqt-notificationd
121 lxqt-openssh-askpass
122 lxqt-policykit
123 lxqt-powermanagement
124 lxqt-qtplugin
125 lxqt-session
126 lxqt-sudo
127 lxqt-themes
128 lxqt-wayland-session
129 pavucontrol-qt
130
131 ### CORE 2
132 lxqt-panel
133 lxqt-runner
134 pcmanfm-qt
135 ];
136
137 optionalPackages = [
138 ### LXQt project
139 qterminal
140 obconf-qt
141 lximage-qt
142 lxqt-archiver
143
144 ### QtDesktop project
145 qps
146 screengrab
147
148 ### Default icon theme
149 kdePackages.breeze-icons
150
151 ### Screen saver
152 pkgs.xscreensaver
153 ];
154
155 };
156in
157makeScope kdePackages.newScope packages