tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 cmake,
6 extra-cmake-modules,
7 pkg-config,
8 httplib,
9 qtbase,
10 qtimageformats,
11 qtwebengine,
12 qtx11extras,
13 libarchive,
14 libXdmcp,
15 libpthreadstubs,
16 wrapQtAppsHook,
17 xcbutilkeysyms,
18}:
19
20let
21 isQt5 = lib.versions.major qtbase.version == "5";
22
23in
24stdenv.mkDerivation (finalAttrs: {
25 pname = "zeal";
26 version = "0.7.2";
27
28 src = fetchFromGitHub {
29 owner = "zealdocs";
30 repo = "zeal";
31 rev = "v${finalAttrs.version}";
32 hash = "sha256-9tlo7+namWNWrWVQNqaOvtK4NQIdb0p8qvFrrbUamOo=";
33 };
34
35 nativeBuildInputs = [
36 cmake
37 extra-cmake-modules
38 pkg-config
39 wrapQtAppsHook
40 ];
41
42 buildInputs = [
43 httplib
44 libXdmcp
45 libarchive
46 libpthreadstubs
47 qtbase
48 qtimageformats
49 qtwebengine
50 xcbutilkeysyms
51 ]
52 ++ lib.optionals isQt5 [ qtx11extras ];
53
54 cmakeFlags = [
55 (lib.cmakeBool "ZEAL_RELEASE_BUILD" true)
56 ];
57
58 meta = {
59 description = "Simple offline API documentation browser";
60 longDescription = ''
61 Zeal is a simple offline API documentation browser inspired by Dash (macOS
62 app), available for Linux and Windows.
63 '';
64 homepage = "https://zealdocs.org/";
65 changelog = "https://github.com/zealdocs/zeal/releases/tag/v${finalAttrs.version}";
66 license = lib.licenses.gpl3Plus;
67 maintainers = with lib.maintainers; [
68 peterhoeg
69 ];
70 mainProgram = "zeal";
71 inherit (qtbase.meta) platforms;
72 };
73})