tjh.dev
1{
2 lib,
3 stdenv,
4 fetchurl,
5 autoPatchelfHook,
6 bluez,
7 libX11,
8 libXtst,
9 makeWrapper,
10}:
11
12stdenv.mkDerivation (finalAttrs: {
13 pname = "urserver";
14 version = "3.13.0.2505";
15
16 src = fetchurl {
17 url = "https://www.unifiedremote.com/static/builds/server/linux-x64/${builtins.elemAt (builtins.splitVersion finalAttrs.version) 3}/urserver-${finalAttrs.version}.tar.gz";
18 hash = "sha256-rklv6Ppha1HhEPunbL8ELYdQ9Z1FN4FrVsNwny3/gA4=";
19 };
20
21 nativeBuildInputs = [
22 autoPatchelfHook
23 makeWrapper
24 ];
25
26 buildInputs = [
27 (lib.getLib stdenv.cc.cc)
28 bluez
29 libX11
30 libXtst
31 ];
32
33 installPhase = ''
34 install -m755 -D urserver $out/bin/urserver
35 wrapProgram $out/bin/urserver --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath finalAttrs.buildInputs}"
36 cp -r remotes $out/bin/remotes
37 cp -r manager $out/bin/manager
38 '';
39
40 meta = with lib; {
41 homepage = "https://www.unifiedremote.com/";
42 description = "One-and-only remote for your computer";
43 sourceProvenance = with sourceTypes; [ binaryNativeCode ];
44 license = licenses.unfree;
45 maintainers = with maintainers; [ sfrijters ];
46 platforms = [ "x86_64-linux" ];
47 };
48})