tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 python3,
4 fetchFromGitHub,
5 desktop-file-utils,
6 glib,
7 gobject-introspection,
8 meson,
9 ninja,
10 wrapGAppsHook4,
11 libadwaita,
12 xdotool,
13 wl-clipboard,
14}:
15
16python3.pkgs.buildPythonApplication rec {
17 pname = "smile";
18 version = "2.10.1";
19 pyproject = false; # Builds with meson
20
21 src = fetchFromGitHub {
22 owner = "mijorus";
23 repo = "smile";
24 tag = version;
25 hash = "sha256-tDdzq2a58x1MVV43IhTZQ/zrVBd2D4BW4102ZEUSWLo=";
26 };
27
28 nativeBuildInputs = [
29 desktop-file-utils # for update-desktop-database
30 glib # for glib-compile-resources
31 gobject-introspection
32 meson
33 ninja
34 wrapGAppsHook4
35 ];
36
37 buildInputs = [
38 libadwaita
39 ];
40
41 dependencies = with python3.pkgs; [
42 dbus-python
43 manimpango
44 pygobject3
45 ];
46
47 dontWrapGApps = true;
48
49 preFixup = ''
50 makeWrapperArgs+=(
51 "''${gappsWrapperArgs[@]}"
52 --prefix PATH : ${
53 lib.makeBinPath [
54 xdotool
55 wl-clipboard
56 ]
57 }
58 )
59 '';
60
61 meta = {
62 changelog = "https://smile.mijorus.it/changelog";
63 description = "Emoji picker for linux, with custom tags support and localization";
64 downloadPage = "https://github.com/mijorus/smile";
65 homepage = "https://mijorus.it/projects/smile/";
66 license = lib.licenses.gpl3Plus;
67 mainProgram = "smile";
68 maintainers = with lib.maintainers; [
69 koppor
70 aleksana
71 ];
72 };
73}