tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchurl,
5 makeWrapper,
6 bash,
7 coreutils,
8 diffstat,
9 diffutils,
10 findutils,
11 gawk,
12 gnugrep,
13 gnused,
14 patch,
15 perl,
16 unixtools,
17}:
18
19stdenv.mkDerivation rec {
20
21 pname = "quilt";
22 version = "0.69";
23
24 src = fetchurl {
25 url = "mirror://savannah/${pname}/${pname}-${version}.tar.gz";
26 sha256 = "sha256-VV3f/eIto8htHK9anB+4oVKsK4RzBDe9OcwIhJyfSFI=";
27 };
28
29 nativeBuildInputs = [ makeWrapper ];
30
31 buildInputs = [
32 bash
33 coreutils
34 diffstat
35 diffutils
36 findutils
37 gawk
38 gnugrep
39 gnused
40 patch
41 perl
42 unixtools.column
43 unixtools.getopt
44 ];
45
46 strictDeps = true;
47
48 configureFlags = [
49 # configure only looks in $PATH by default,
50 # which does not include buildInputs if strictDeps is true
51 "--with-perl=${lib.getExe perl}"
52 ];
53
54 postInstall = ''
55 wrapProgram $out/bin/quilt --prefix PATH : ${lib.makeBinPath buildInputs}
56 '';
57
58 meta = with lib; {
59 homepage = "https://savannah.nongnu.org/projects/quilt";
60 description = "Easily manage large numbers of patches";
61
62 longDescription = ''
63 Quilt allows you to easily manage large numbers of
64 patches by keeping track of the changes each patch
65 makes. Patches can be applied, un-applied, refreshed,
66 and more.
67 '';
68
69 license = licenses.gpl2Plus;
70 maintainers = with maintainers; [ smancill ];
71 platforms = platforms.all;
72 };
73
74}