tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 stdenv,
3 lib,
4 fetchurl,
5 zlib,
6 curl,
7 xz,
8 patchelf,
9 runtimeShell,
10}:
11
12let
13 version = "2.7.3";
14
15 inherit (stdenv.hostPlatform) system;
16
17 srcs = {
18 x86_64-linux = fetchurl {
19 url = "https://static-meteor.netdna-ssl.com/packages-bootstrap/${version}/meteor-bootstrap-os.linux.x86_64.tar.gz";
20 sha256 = "sha256-ovsE7jUJIKf96WEoITXECUlPo+o1tEKvHzCc7Xgj614=";
21 };
22 x86_64-darwin = fetchurl {
23 url = "https://static-meteor.netdna-ssl.com/packages-bootstrap/${version}/meteor-bootstrap-os.osx.x86_64.tar.gz";
24 sha256 = "11206dbda50a680fdab7044def7ea68ea8f4a9bca948ca56df91fe1392b2ac16";
25 };
26 };
27in
28
29stdenv.mkDerivation {
30 inherit version;
31 pname = "meteor";
32 src = srcs.${system} or (throw "unsupported system ${system}");
33
34 #dontStrip = true;
35
36 sourceRoot = ".meteor";
37
38 installPhase = ''
39 mkdir $out
40
41 cp -r packages $out
42 chmod -R +w $out/packages
43
44 cp -r package-metadata $out
45
46 devBundle=$(find $out/packages/meteor-tool -name dev_bundle)
47 ln -s $devBundle $out/dev_bundle
48
49 toolsDir=$(dirname $(find $out/packages -print | grep "meteor-tool/.*/tools/index.js$"))
50 ln -s $toolsDir $out/tools
51
52 # Meteor needs an initial package-metadata in $HOME/.meteor,
53 # otherwise it fails spectacularly.
54 mkdir -p $out/bin
55 cat << EOF > $out/bin/meteor
56 #!${runtimeShell}
57
58 if [[ ! -f \$HOME/.meteor/package-metadata/v2.0.1/packages.data.db ]]; then
59 mkdir -p \$HOME/.meteor/package-metadata/v2.0.1
60 cp $out/package-metadata/v2.0.1/packages.data.db "\$HOME/.meteor/package-metadata/v2.0.1"
61 chown "\$(whoami)" "\$HOME/.meteor/package-metadata/v2.0.1/packages.data.db"
62 chmod +w "\$HOME/.meteor/package-metadata/v2.0.1/packages.data.db"
63 fi
64
65 $out/dev_bundle/bin/node --no-wasm-code-gc \''${TOOL_NODE_FLAGS} $out/tools/index.js "\$@"
66 EOF
67 chmod +x $out/bin/meteor
68 '';
69
70 postFixup = lib.optionalString stdenv.hostPlatform.isLinux ''
71 # Patch Meteor to dynamically fixup shebangs and ELF metadata where
72 # necessary.
73 pushd $out
74 patch -p1 < ${./main.patch}
75 popd
76 substituteInPlace $out/tools/cli/main.js \
77 --replace "@INTERPRETER@" "$(cat $NIX_CC/nix-support/dynamic-linker)" \
78 --replace "@RPATH@" "${
79 lib.makeLibraryPath [
80 stdenv.cc.cc
81 zlib
82 curl
83 xz
84 ]
85 }" \
86 --replace "@PATCHELF@" "${patchelf}/bin/patchelf"
87
88 # Patch node.
89 patchelf \
90 --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
91 --set-rpath "$(patchelf --print-rpath $out/dev_bundle/bin/node):${lib.getLib stdenv.cc.cc}/lib" \
92 $out/dev_bundle/bin/node
93
94 # Patch mongo.
95 for p in $out/dev_bundle/mongodb/bin/mongo{,d}; do
96 patchelf \
97 --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
98 --set-rpath "$(patchelf --print-rpath $p):${
99 lib.makeLibraryPath [
100 stdenv.cc.cc
101 zlib
102 curl
103 xz
104 ]
105 }" \
106 $p
107 done
108
109 # Patch node dlls.
110 for p in $(find $out/packages -name '*.node'); do
111 patchelf \
112 --set-rpath "$(patchelf --print-rpath $p):${lib.getLib stdenv.cc.cc}/lib" \
113 $p || true
114 done
115 '';
116
117 meta = with lib; {
118 description = "Complete open source platform for building web and mobile apps in pure JavaScript";
119 homepage = "https://www.meteor.com/";
120 sourceProvenance = with sourceTypes; [ binaryNativeCode ];
121 license = licenses.mit;
122 platforms = builtins.attrNames srcs;
123 maintainers = [ ];
124 mainProgram = "meteor";
125 };
126}