tjh.dev
Clone of https://github.com/NixOS/nixpkgs.git (to stress-test knotserver)
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 autoreconfHook,
6 keyutils,
7 libkrb5,
8 openafs,
9 perl,
10 pkg-config,
11 enableSetPAG ? false,
12}:
13
14stdenv.mkDerivation (finalAttrs: {
15 pname = "kstart";
16 version = "4.3";
17
18 src = fetchFromGitHub {
19 owner = "rra";
20 repo = "kstart";
21 rev = "release/${finalAttrs.version}";
22 hash = "sha256-MGWL4oNc0MZTGWqBEt2wRTkqoagiUTDrS0kz4ewbZZA=";
23 };
24
25 nativeBuildInputs = [
26 autoreconfHook
27 perl
28 pkg-config
29 ];
30
31 buildInputs = [
32 keyutils
33 libkrb5
34 openafs
35 ];
36
37 configureFlags = [
38 "--enable-silent-rules"
39 ]
40 ++ (lib.optional enableSetPAG "--enable-setpag");
41
42 preBuild = ''
43 for f in k5start krenew; do
44 pod2man --release="${finalAttrs.version}" --center="kstart" docs/"$f".pod >docs/"$f".1
45 done
46 '';
47
48 doCheck = true;
49 preCheck = ''
50 patchShebangs tests
51 '';
52
53 outputs = [
54 "out"
55 "man"
56 ];
57
58 meta = with lib; {
59 outputsToInstall = [
60 "out"
61 "man"
62 ];
63 description = "Modified version of kerberos tools that support automatic ticket refresh";
64 license = licenses.mit;
65 platforms = platforms.linux ++ platforms.darwin;
66 };
67})