tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchurl,
5 autoreconfHook,
6 gtk-doc,
7 withShishi ? !stdenv.hostPlatform.isDarwin,
8 shishi,
9}:
10
11stdenv.mkDerivation rec {
12 pname = "gss";
13 version = "1.0.4";
14
15 src = fetchurl {
16 url = "mirror://gnu/gss/gss-${version}.tar.gz";
17 hash = "sha256-7M6r3vTK4/znIYsuy4PrQifbpEtTthuMKy6IrgJBnHM=";
18 };
19
20 # krb5context test uses certificates that expired on 2024-07-11.
21 # Reported to bug-gss@gnu.org with Message-ID: <87cyngavtt.fsf@alyssa.is>.
22 postPatch = ''
23 rm tests/krb5context.c
24 '';
25
26 nativeBuildInputs = [
27 autoreconfHook
28 gtk-doc
29 ];
30
31 buildInputs = lib.optional withShishi shishi;
32
33 # ./stdint.h:89:5: error: expected value in expression
34 preConfigure = lib.optionalString stdenv.hostPlatform.isDarwin ''
35 export GNULIBHEADERS_OVERRIDE_WINT_T=0
36 '';
37
38 configureFlags = [
39 "--${if withShishi then "enable" else "disable"}-kerberos5"
40 ];
41
42 # Fixup .la files
43 postInstall = lib.optionalString withShishi ''
44 sed -i 's,\(-lshishi\),-L${shishi}/lib \1,' $out/lib/libgss.la
45 '';
46
47 meta = with lib; {
48 homepage = "https://www.gnu.org/software/gss/";
49 description = "Generic Security Service";
50 mainProgram = "gss";
51 license = licenses.gpl3Plus;
52 maintainers = [ ];
53 platforms = platforms.all;
54 };
55}