tjh.dev
1{
2 lib,
3 stdenvNoCC,
4 fetchFromGitHub,
5 buildDotnetModule,
6 dotnetCorePackages,
7 unstableGitUpdater,
8}:
9
10buildDotnetModule (finalAttrs: {
11 pname = "formula-dotnet";
12 version = "2.0";
13
14 src = fetchFromGitHub {
15 owner = "VUISIS";
16 repo = "formula-dotnet";
17 rev = "8ee2e6abfd4ce038e1d9cb9c8602dec1ed6c0163";
18 hash = "sha256-2ulv//YV3OqrfFltgUCeDe4rOPC0qqJ+80/D2lIoih8=";
19 };
20
21 patches = [ ./dotnet-8-upgrade.patch ];
22
23 dotnet-sdk = dotnetCorePackages.sdk_8_0;
24 nugetDeps = ./nuget.json;
25 projectFile = "Src/CommandLine/CommandLine.csproj";
26
27 postFixup =
28 lib.optionalString stdenvNoCC.hostPlatform.isLinux ''
29 mv $out/bin/CommandLine $out/bin/formula
30 ''
31 + lib.optionalString stdenvNoCC.hostPlatform.isDarwin ''
32 makeWrapper ${dotnetCorePackages.runtime_8_0}/bin/dotnet $out/bin/formula \
33 --add-flags "$out/lib/formula-dotnet/CommandLine.dll" \
34 --prefix DYLD_LIBRARY_PATH : $out/lib/formula-dotnet/runtimes/macos/native
35 '';
36
37 passthru.updateScript = unstableGitUpdater { url = finalAttrs.meta.homepage; };
38
39 meta = with lib; {
40 description = "Formal Specifications for Verification and Synthesis";
41 homepage = "https://github.com/VUISIS/formula-dotnet";
42 license = licenses.mspl;
43 maintainers = with maintainers; [ siraben ];
44 platforms = platforms.unix;
45 mainProgram = "formula";
46 };
47})