tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchurl,
5 autoPatchelfHook,
6}:
7
8let
9 srcs = {
10 x86_64-linux = fetchurl {
11 urls = [
12 "https://videomap.it/script/dms-ubuntu-x64"
13 "https://archive.org/download/videomap/dms-ubuntu-x64"
14 ];
15 sha256 = "1x7pp6k27lr206a8j2pn0wf4wjb0zi28s0g1g3rb08jmr8fh1jnh";
16 };
17 i686-linux = fetchurl {
18 urls = [
19 "https://videomap.it/script/dms-ubuntu-x32"
20 "https://archive.org/download/videomap/dms-ubuntu-x32"
21 ];
22 sha256 = "1d62d7jz50wzk5rqqm3xab66jdzi9i1j6mwxf7r7nsgm6j5zz8r4";
23 };
24 aarch64-linux = fetchurl {
25 urls = [
26 "https://videomap.it/script/dms-ubuntu-arm64"
27 "https://archive.org/download/videomap/dms-ubuntu-arm64"
28 ];
29 sha256 = "1l1x7iqbxn6zsh3d37yb5x15qsxlwy3cz8g2g8vnzkgaafw9vva0";
30 };
31 armv7l-linux = fetchurl {
32 urls = [
33 "https://videomap.it/script/dms-ubuntu-arm"
34 "https://archive.org/download/videomap/dms-ubuntu-arm"
35 ];
36 sha256 = "1i7q9mylzvbsfydv4xf83nyqkh0nh01612jrqm93q1w6d0k2zvcd";
37 };
38 };
39in
40stdenv.mkDerivation {
41 pname = "droidmote";
42 version = "3.0.6";
43
44 src =
45 srcs.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
46
47 dontUnpack = true;
48 dontBuild = true;
49
50 nativeBuildInputs = [ autoPatchelfHook ];
51
52 installPhase = ''
53 runHook preInstall
54
55 install -m755 -D $src $out/bin/droidmote
56
57 runHook postInstall
58 '';
59
60 meta = with lib; {
61 description = "Control your computer from your couch";
62 homepage = "https://www.videomap.it/";
63 sourceProvenance = with sourceTypes; [ binaryNativeCode ];
64 license = licenses.unfree;
65 maintainers = with maintainers; [ atila ];
66 platforms = lib.attrNames srcs;
67 };
68}