tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchurl,
5 fetchpatch,
6 autoreconfHook,
7 neon,
8 procps,
9 replaceVars,
10 zlib,
11 wrapperDir ? "/run/wrappers/bin",
12}:
13
14stdenv.mkDerivation (finalAttrs: {
15 pname = "davfs2";
16 version = "1.7.1";
17
18 src = fetchurl {
19 url = "mirror://savannah/davfs2/davfs2-${finalAttrs.version}.tar.gz";
20 sha256 = "sha256-KY7dDGdzy+JY4VUqQxrK6msu7bcIeImnNdrviIX8saw=";
21 };
22
23 nativeBuildInputs = [
24 autoreconfHook
25 ];
26
27 buildInputs = [
28 zlib
29 ];
30
31 patches = [
32 ./fix-sysconfdir.patch
33 ./disable-suid.patch
34 (replaceVars ./0001-umount_davfs-substitute-ps-command.patch {
35 ps = "${procps}/bin/ps";
36 })
37 (replaceVars ./0002-Make-sure-that-the-setuid-wrapped-umount-is-invoked.patch {
38 inherit wrapperDir;
39 })
40 (fetchpatch {
41 name = "neon-34.patch";
42 url = "https://github.com/alisarctl/davfs2/commit/2693a9a2656b70a64ee851d5c22a2945d840dcbb.diff";
43 hash = "sha256-KK+4cjrUrWcyY6F5otNgrZ4BojJ4NiMm/Y1zejCt4Tc=";
44 })
45 ];
46
47 configureFlags = [
48 "--sysconfdir=/etc"
49 "--with-neon=${lib.getLib neon}"
50 ];
51
52 meta = {
53 homepage = "https://savannah.nongnu.org/projects/davfs2";
54 description = "Mount WebDAV shares like a typical filesystem";
55 license = lib.licenses.gpl3Plus;
56
57 longDescription = ''
58 Web Distributed Authoring and Versioning (WebDAV), an extension to
59 the HTTP-protocol, allows authoring of resources on a remote web
60 server. davfs2 provides the ability to access such resources like
61 a typical filesystem, allowing for use by standard applications
62 with no built-in support for WebDAV.
63 '';
64
65 platforms = lib.platforms.linux;
66 maintainers = with lib.maintainers; [ fgaz ];
67 };
68})