tjh.dev
1{
2 lib,
3 stdenvNoCC,
4 fetchFromGitLab,
5 bdfresize,
6 perl,
7 unifont,
8 dejavu_fonts,
9 otf2bdf,
10 gitUpdater,
11}:
12
13stdenvNoCC.mkDerivation (finalAttrs: {
14 pname = "console-setup";
15 version = "1.239";
16
17 src = fetchFromGitLab {
18 domain = "salsa.debian.org";
19 owner = "installer-team";
20 repo = "console-setup";
21 tag = finalAttrs.version;
22 hash = "sha256-jyV+tgasZPjidcOmWhnK/ggf+ocN8ZZODMQfA6ZAHcc=";
23 };
24
25 buildInputs = [
26 bdfresize
27 otf2bdf
28 perl
29 ];
30
31 makeFlags = [ "prefix=${placeholder "out"}" ];
32
33 enableParallelBuilding = true;
34
35 postPatch = ''
36 patchShebangs .
37 substituteInPlace Fonts/Makefile --replace-fail '/usr/share/fonts/truetype/dejavu/' '${dejavu_fonts}/share/fonts/truetype/'
38 ln -s ${unifont}/share/fonts/unifont.bdf Fonts/bdf
39 substituteInPlace Fonts/Makefile --replace-fail 'rm -f $(fntdir)/bdf/unifont.bdf' ""
40 '';
41
42 preBuild = "make -j$NIX_BUILD_CORES bdf";
43
44 installTargets = [ "install-linux" ];
45
46 passthru.updateScript = gitUpdater { };
47
48 meta = {
49 description = "Console font and keymap setup program";
50 homepage = "https://salsa.debian.org/installer-team/console-setup";
51 license = lib.licenses.gpl2Only;
52 platforms = lib.platforms.all;
53 maintainers = with lib.maintainers; [ ners ];
54 mainProgram = "setupcon";
55 };
56})