tjh.dev
1{
2 lib,
3 stdenv,
4 fetchurl,
5 makeWrapper,
6 gtk2,
7 libcddb,
8 intltool,
9 pkg-config,
10 cdparanoia,
11 mp3Support ? false,
12 lame,
13 oggSupport ? true,
14 vorbis-tools,
15 flacSupport ? true,
16 flac,
17 opusSupport ? false,
18 opusTools,
19 wavpackSupport ? false,
20 wavpack,
21 #, musepackSupport ? false, TODO: mpcenc
22 monkeysAudioSupport ? false,
23 monkeysAudio,
24#, aacSupport ? false, TODO: neroAacEnc
25}:
26
27stdenv.mkDerivation rec {
28 version = "3.0.1";
29 pname = "asunder";
30 src = fetchurl {
31 url = "http://littlesvr.ca/asunder/releases/${pname}-${version}.tar.bz2";
32 sha256 = "sha256-iGji4bl7ZofIAOf2EiYqMWu4V+3TmIN2jOYottJTN2s=";
33 };
34
35 nativeBuildInputs = [
36 intltool
37 makeWrapper
38 pkg-config
39 ];
40 buildInputs = [
41 gtk2
42 libcddb
43 ];
44
45 runtimeDeps =
46 lib.optional mp3Support lame
47 ++ lib.optional oggSupport vorbis-tools
48 ++ lib.optional flacSupport flac
49 ++ lib.optional opusSupport opusTools
50 ++ lib.optional wavpackSupport wavpack
51 ++ lib.optional monkeysAudioSupport monkeysAudio
52 ++ [ cdparanoia ];
53
54 postInstall = ''
55 wrapProgram "$out/bin/asunder" \
56 --prefix PATH : "${lib.makeBinPath runtimeDeps}"
57 '';
58
59 meta = with lib; {
60 description = "Graphical Audio CD ripper and encoder for Linux";
61 mainProgram = "asunder";
62 homepage = "http://littlesvr.ca/asunder/index.php";
63 license = licenses.gpl2;
64 maintainers = with maintainers; [ mudri ];
65 platforms = platforms.linux;
66
67 longDescription = ''
68 Asunder is a graphical Audio CD ripper and encoder for Linux. You can use
69 it to save tracks from an Audio CD as any of WAV, MP3, OGG, FLAC, Opus,
70 WavPack, Musepack, AAC, and Monkey's Audio files.
71 '';
72 };
73}