tjh.dev
1{
2 lib,
3 stdenv,
4 vdr,
5 fetchFromGitHub,
6 graphicsmagick,
7 boost186,
8 libgcrypt,
9 ncurses,
10 callPackage,
11}:
12let
13 mkPlugin =
14 name:
15 stdenv.mkDerivation {
16 name = "vdr-${name}-${vdr.version}";
17 inherit (vdr) src;
18 buildInputs = [ vdr ];
19 preConfigure = "cd PLUGINS/src/${name}";
20 installFlags = [ "DESTDIR=$(out)" ];
21 };
22in
23{
24
25 epgsearch = callPackage ./epgsearch { };
26
27 markad = callPackage ./markad { };
28
29 nopacity = callPackage ./nopacity { };
30
31 softhddevice = callPackage ./softhddevice { };
32
33 streamdev = callPackage ./streamdev { };
34
35 xineliboutput = callPackage ./xineliboutput { };
36
37 skincurses = (mkPlugin "skincurses").overrideAttrs (oldAttr: {
38 buildInputs = oldAttr.buildInputs ++ [ ncurses ];
39 });
40
41 inherit
42 (lib.genAttrs [
43 "epgtableid0"
44 "hello"
45 "osddemo"
46 "pictures"
47 "servicedemo"
48 "status"
49 "svdrpdemo"
50 ] mkPlugin)
51 ;
52
53 femon = stdenv.mkDerivation rec {
54 pname = "vdr-femon";
55 version = "2.4.0";
56
57 buildInputs = [ vdr ];
58
59 src = fetchFromGitHub {
60 repo = "vdr-plugin-femon";
61 owner = "rofafor";
62 sha256 = "sha256-0qBMYgNKk7N9Bj8fAoOokUo+G9gfj16N5e7dhoKRBqs=";
63 rev = "v${version}";
64 };
65
66 postPatch = "substituteInPlace Makefile --replace /bin/true true";
67
68 makeFlags = [ "DESTDIR=$(out)" ];
69
70 meta = with lib; {
71 inherit (src.meta) homepage;
72 description = "DVB Frontend Status Monitor plugin for VDR";
73 maintainers = [ maintainers.ck3d ];
74 license = licenses.gpl2;
75 inherit (vdr.meta) platforms;
76 };
77
78 };
79
80 vnsiserver = stdenv.mkDerivation rec {
81 pname = "vdr-vnsiserver";
82 version = "1.8.3";
83
84 buildInputs = [ vdr ];
85
86 installFlags = [ "DESTDIR=$(out)" ];
87
88 src = fetchFromGitHub {
89 repo = "vdr-plugin-vnsiserver";
90 owner = "vdr-projects";
91 rev = version;
92 sha256 = "sha256-ivHdzX90ozMXSvIc5OrKC5qHeK5W3TK8zyrN8mY3IhE=";
93 };
94
95 meta = with lib; {
96 inherit (src.meta) homepage;
97 description = "VDR plugin to handle KODI clients";
98 maintainers = [ maintainers.ck3d ];
99 license = licenses.gpl2;
100 inherit (vdr.meta) platforms;
101 };
102
103 };
104
105 text2skin = stdenv.mkDerivation rec {
106 pname = "vdr-text2skin";
107 version = "1.3.4-20170702";
108
109 src = fetchFromGitHub {
110 repo = "vdr-plugin-text2skin";
111 owner = "vdr-projects";
112 rev = "8f7954da2488ced734c30e7c2704b92a44e6e1ad";
113 sha256 = "19hkwmaw6nwak38bv6cm2vcjjkf4w5yjyxb98qq6zfjjh5wq54aa";
114 };
115
116 buildInputs = [
117 vdr
118 graphicsmagick
119 ];
120
121 buildFlags = [
122 "DESTDIR=$(out)"
123 "IMAGELIB=graphicsmagic"
124 "VDRDIR=${vdr.dev}/include/vdr"
125 "LOCALEDIR=$(DESTDIR)/share/locale"
126 "LIBDIR=$(DESTDIR)/lib/vdr"
127 ];
128
129 preBuild = ''
130 mkdir -p $out/lib/vdr
131 '';
132
133 dontInstall = true;
134
135 meta = with lib; {
136 inherit (src.meta) homepage;
137 description = "VDR Text2Skin Plugin";
138 maintainers = [ maintainers.ck3d ];
139 license = licenses.gpl2;
140 inherit (vdr.meta) platforms;
141 };
142 };
143
144 fritzbox = stdenv.mkDerivation rec {
145 pname = "vdr-fritzbox";
146 version = "1.5.4";
147
148 src = fetchFromGitHub {
149 owner = "jowi24";
150 repo = "vdr-fritz";
151 rev = version;
152 hash = "sha256-DGD73i+ZHFgtCo+pMj5JaMovvb5vS1x20hmc5t29//o=";
153 fetchSubmodules = true;
154 };
155
156 buildInputs = [
157 vdr
158 boost186
159 libgcrypt
160 ];
161
162 installFlags = [ "DESTDIR=$(out)" ];
163
164 meta = with lib; {
165 inherit (src.meta) homepage;
166 description = "Plugin for VDR to access AVMs Fritz Box routers";
167 maintainers = [ maintainers.ck3d ];
168 license = licenses.gpl2;
169 inherit (vdr.meta) platforms;
170 };
171 };
172}