tjh.dev
1{
2 mkDerivation,
3 lib,
4 fetchbzr,
5 python3,
6 rtmpdump,
7}:
8
9let
10 pythonEnv = python3.withPackages (
11 ps: with ps; [
12 m3u8
13 pyqt5-multimedia
14 ]
15 );
16in
17mkDerivation {
18 pname = "qarte";
19 version = "5.5.0";
20
21 src = fetchbzr {
22 url = "http://bazaar.launchpad.net/~vincent-vandevyvre/qarte/qarte-5";
23 rev = "88";
24 sha256 = "sha256-+Ixe4bWKubH/XBESwmP2NWS8bH0jq611c3MZn7W87Jw=";
25 };
26
27 buildInputs = [ pythonEnv ];
28
29 installPhase = ''
30 runHook preInstall
31
32 mkdir -p $out/bin
33 mv qarte $out/bin/
34 substituteInPlace $out/bin/qarte \
35 --replace '/usr/share' "$out/share"
36
37 mkdir -p $out/share/man/man1/
38 mv qarte.1 $out/share/man/man1/
39
40 mkdir -p $out/share/qarte
41 mv * $out/share/qarte/
42
43 runHook postInstall
44 '';
45
46 postFixup = ''
47 wrapQtApp $out/bin/qarte \
48 --prefix PATH : ${rtmpdump}/bin
49 '';
50
51 meta = with lib; {
52 homepage = "https://launchpad.net/qarte";
53 description = "Recorder for Arte TV Guide and Arte Concert";
54 license = licenses.gpl3;
55 maintainers = with maintainers; [ vbgl ];
56 platforms = platforms.linux;
57 mainProgram = "qarte";
58 };
59}