tjh.dev
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 fftw,
6 libjpeg,
7 log4cpp,
8 openjpeg,
9 libpng12,
10 poppler,
11 qtbase,
12 qt5,
13 qmake,
14 wrapQtAppsHook,
15}:
16
17stdenv.mkDerivation rec {
18 pname = "engauge-digitizer";
19 version = "12.2.2";
20
21 src = fetchFromGitHub {
22 owner = "markummitchell";
23 repo = pname;
24 rev = "v${version}";
25 sha256 = "sha256-Wj9o3wWbtHsEi6LFH4xDpwVR9BwcWc472jJ/QFDQZvY=";
26 };
27
28 nativeBuildInputs = [
29 qmake
30 wrapQtAppsHook
31 ];
32
33 buildInputs = [
34 qtbase
35 qt5.qttools
36 poppler
37 libpng12
38 openjpeg
39 openjpeg.dev
40 log4cpp
41 libjpeg
42 fftw
43 ];
44
45 qmakeFlags = [
46 "CONFIG+=jpeg2000"
47 "CONFIG+=pdf"
48 "CONFIG+=log4cpp_null"
49 ];
50
51 POPPLER_INCLUDE = "${poppler.dev}/include/poppler/qt5";
52
53 POPPLER_LIB = "${poppler}/lib";
54
55 OPENJPEG_INCLUDE = "${openjpeg.dev}/include/${openjpeg.pname}-${lib.versions.majorMinor openjpeg.version}";
56
57 OPENJPEG_LIB = "${openjpeg}/lib";
58
59 installPhase = ''
60 runHook preInstall
61
62 mkdir -p $out/bin
63 cp bin/engauge $out/bin/
64
65 runHook postInstall
66 '';
67
68 meta = with lib; {
69 description = "Engauge Digitizer is a tool for recovering graph data from an image file";
70 mainProgram = "engauge";
71 homepage = "https://markummitchell.github.io/engauge-digitizer";
72 license = with licenses; [ gpl2Only ];
73 platforms = platforms.linux;
74 maintainers = [ maintainers.sheepforce ];
75 };
76}