tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchFromGitLab,
5 installShellFiles,
6 qmake,
7 qttools,
8 qtsvg,
9 qtxmlpatterns,
10 wrapQtAppsHook,
11 autoPatchelfHook,
12}:
13
14stdenv.mkDerivation rec {
15 pname = "valentina";
16 version = "0.7.53";
17
18 src = fetchFromGitLab {
19 owner = "smart-pattern";
20 repo = "valentina";
21 rev = "v${version}";
22 hash = "sha256-vIlqrK7wyFaXKfvcJ3FtkAwUt6Xb/47qxcDGy1Ty2uk=";
23 };
24
25 postPatch = ''
26 substituteInPlace src/app/translations.pri \
27 --replace '$$[QT_INSTALL_BINS]/$$LRELEASE' '${lib.getDev qttools}/bin/lrelease'
28 '';
29
30 nativeBuildInputs = [
31 qmake
32 qttools
33 wrapQtAppsHook
34 installShellFiles
35 autoPatchelfHook
36 ];
37
38 buildInputs = [
39 qtsvg
40 qtxmlpatterns
41 ];
42
43 qmakeFlags = [
44 "-r"
45 "PREFIX=${placeholder "out"}"
46 "CONFIG+=noTests"
47 "CONFIG+=noRunPath"
48 "CONFIG+=no_ccache"
49 "CONFIG+=noDebugSymbols"
50 ];
51
52 postInstall = ''
53 installManPage dist/debian/*.1
54 install -Dm644 dist/debian/valentina.sharedmimeinfo $out/share/mime/packages/valentina.xml
55 '';
56
57 meta = {
58 description = "Open source sewing pattern drafting software";
59 homepage = "https://smart-pattern.com.ua/";
60 changelog = "https://gitlab.com/smart-pattern/valentina/-/blob/v${version}/ChangeLog.txt";
61 license = lib.licenses.gpl3Plus;
62 platforms = lib.platforms.linux;
63 maintainers = with lib.maintainers; [ ];
64 };
65}