tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 installShellFiles,
6 pkg-config,
7 qmake,
8 qtbase,
9 kcoreaddons,
10 kwidgetsaddons,
11 qtsvg,
12 wrapQtAppsHook,
13}:
14
15stdenv.mkDerivation rec {
16 pname = "qelectrotech";
17 version = "0.9.0";
18
19 src = fetchFromGitHub {
20 owner = "qelectrotech";
21 repo = "qelectrotech-source-mirror";
22 tag = "0.9";
23 hash = "sha256-tj8q+mRVtdeDXbpiv4retdbNiIfvAFlutXn7BmjqFYU=";
24 };
25
26 postPatch = ''
27 substituteInPlace qelectrotech.pro \
28 --replace-fail 'GIT_COMMIT_SHA="\\\"$(shell git -C \""$$_PRO_FILE_PWD_"\" rev-parse --verify HEAD)\\\""' \
29 'GIT_COMMIT_SHA="\\\"${version}\\\""' \
30 --replace-fail "COMPIL_PREFIX = '/usr/local/'" \
31 "COMPIL_PREFIX = '$out/'" \
32 --replace-fail "INSTALL_PREFIX = '/usr/local/'" \
33 "INSTALL_PREFIX = '$out/'"
34 '';
35
36 nativeBuildInputs = [
37 installShellFiles
38 pkg-config
39 qmake
40 wrapQtAppsHook
41 ];
42
43 buildInputs = [
44 kcoreaddons
45 kwidgetsaddons
46 qtbase
47 qtsvg
48 ];
49
50 qmakeFlags = [
51 "INSTALLROOT=$(out)"
52 ];
53
54 installPhase = ''
55 runHook preInstall
56
57 install -Dm555 qelectrotech $out/bin/qelectrotech
58
59 install -Dm444 -t $out/share/applications misc/qelectrotech.desktop
60
61 mkdir -p $out/share/qelectrotech
62 cp -r elements $out/share/qelectrotech
63 cp -r titleblocks $out/share/qelectrotech
64 cp -r lang $out/share/qelectrotech
65 cp -r examples $out/share/qelectrotech
66
67 mkdir -p $out/share/icons/hicolor
68 cp -r ico $out/share/icons/hicolor
69
70 runHook postInstall
71 '';
72
73 meta = {
74 description = "Free software to create electric diagrams";
75 mainProgram = "qelectrotech";
76 homepage = "https://qelectrotech.org/";
77 license = lib.licenses.gpl2;
78 maintainers = with lib.maintainers; [ yvesf ];
79 platforms = qtbase.meta.platforms;
80 broken = stdenv.hostPlatform.isDarwin;
81 };
82}