tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1/*
2 # New packages
3
4 READ THIS FIRST
5
6 This module is for the MauiKit framework and official Maui applications. All
7 available packages are listed in `callPackage ./srcs.nix`, although some are not yet
8 packaged in Nixpkgs.
9
10 IF YOUR PACKAGE IS NOT LISTED IN `callPackage ./srcs.nix`, IT DOES NOT GO HERE.
11
12 See also `pkgs/applications/kde` as this is what this is based on.
13
14 # Updates
15
16 1. Update the URL in `./fetch.sh`.
17 2. Run `./maintainers/scripts/fetch-kde-qt.sh pkgs/applications/maui`
18 from the top of the Nixpkgs tree.
19 3. Use `nixpkgs-review wip` to check that everything builds.
20 4. Commit the changes and open a pull request.
21*/
22
23{
24 lib,
25 libsForQt5,
26 fetchurl,
27}:
28
29let
30 mirror = "mirror://kde";
31 srcs = import ./srcs.nix { inherit fetchurl mirror; };
32
33 mkDerivation =
34 args:
35 let
36 inherit (args) pname;
37 inherit (srcs.${pname}) src version;
38 mkDerivation = libsForQt5.callPackage ({ mkDerivation }: mkDerivation) { };
39 in
40 mkDerivation (
41 args
42 // {
43 inherit pname version src;
44
45 outputs = args.outputs or [ "out" ];
46
47 meta =
48 let
49 meta = args.meta or { };
50 in
51 meta
52 // {
53 homepage = meta.homepage or "https://mauikit.org/";
54 platforms = meta.platforms or lib.platforms.linux;
55 };
56 }
57 );
58
59 packages =
60 self:
61 let
62 callPackage = self.newScope {
63 inherit mkDerivation;
64 };
65 in
66 {
67 # libraries
68 mauikit = callPackage ./mauikit.nix { };
69 mauikit-accounts = callPackage ./mauikit-accounts.nix { };
70 mauikit-calendar = callPackage ./mauikit-calendar { };
71 mauikit-documents = callPackage ./mauikit-documents.nix { };
72 mauikit-filebrowsing = callPackage ./mauikit-filebrowsing.nix { };
73 mauikit-imagetools = callPackage ./mauikit-imagetools.nix { };
74 mauikit-terminal = callPackage ./mauikit-terminal.nix { };
75 mauikit-texteditor = callPackage ./mauikit-texteditor.nix { };
76 mauiman = callPackage ./mauiman.nix { };
77
78 # applications
79 booth = callPackage ./booth.nix { };
80 buho = callPackage ./buho.nix { };
81 clip = callPackage ./clip.nix { };
82 communicator = callPackage ./communicator.nix { };
83 index = callPackage ./index.nix { };
84 nota = callPackage ./nota.nix { };
85 pix = callPackage ./pix.nix { };
86 shelf = callPackage ./shelf.nix { };
87 station = callPackage ./station.nix { };
88 vvave = callPackage ./vvave.nix { };
89 };
90
91in
92lib.makeScope libsForQt5.newScope packages