tjh.dev
1{
2 fetchFromGitHub,
3 nix-update-script,
4 rustPlatform,
5 vimUtils,
6}:
7let
8 version = "0-unstable-2022-06-14";
9 src = fetchFromGitHub {
10 owner = "euclio";
11 repo = "vim-markdown-composer";
12 rev = "e6f99bc20cfcb277c63041b1f766e6d5940bcc76";
13 sha256 = "0ljv8cvca8nk91g67mnzip81say04b1wbj9bzcgzy8m6qkz1r2h3";
14 fetchSubmodules = true;
15 };
16
17 vim-markdown-composer-bin = rustPlatform.buildRustPackage {
18 pname = "vim-markdown-composer-bin";
19 inherit src version;
20
21 cargoHash = "sha256-xzlEIaDEYDbxJ6YqzF+lSHcB9O+brClw026YI1YeNUc=";
22 # tests require network access
23 doCheck = false;
24 };
25in
26vimUtils.buildVimPlugin {
27 pname = "vim-markdown-composer";
28 inherit version src;
29
30 preFixup = ''
31 substituteInPlace "$out"/after/ftplugin/markdown/composer.vim \
32 --replace-fail \
33 "s:plugin_root . '/target/release/markdown-composer'" \
34 "'${vim-markdown-composer-bin}/bin/markdown-composer'"
35 '';
36
37 passthru = {
38 updateScript = nix-update-script {
39 extraArgs = [ "--version=branch" ];
40 attrPath = "vimPlugins.vim-markdown-composer.vim-markdown-composer-bin";
41 };
42
43 # needed for the update script
44 inherit vim-markdown-composer-bin;
45 };
46
47 meta = {
48 homepage = "https://github.com/euclio/vim-markdown-composer/";
49 # rust build error
50 broken = true;
51 };
52}