tjh.dev
1# Based on https://github.com/justinwoo/easy-purescript-nix/blob/master/psc-package-simple.nix
2{ stdenv, lib, fetchurl, gmp, zlib, libiconv, darwin, installShellFiles }:
3
4let
5 dynamic-linker = stdenv.cc.bintools.dynamicLinker;
6
7in
8stdenv.mkDerivation rec {
9 pname = "psc-package-simple";
10
11 version = "0.6.2";
12
13 src = if stdenv.isDarwin
14 then fetchurl {
15 url = "https://github.com/purescript/psc-package/releases/download/v0.6.2/macos.tar.gz";
16 sha256 = "17dh3bc5b6ahfyx0pi6n9qnrhsyi83qdynnca6k1kamxwjimpcq1";
17 }
18 else fetchurl {
19 url = "https://github.com/purescript/psc-package/releases/download/v0.6.2/linux64.tar.gz";
20 sha256 = "1zvay9q3xj6yd76w6qyb9la4jaj9zvpf4dp78xcznfqbnbhm1a54";
21 };
22
23 buildInputs = [ gmp zlib ];
24 nativeBuildInputs = [ installShellFiles ];
25
26 libPath = lib.makeLibraryPath buildInputs;
27
28 dontStrip = true;
29
30 installPhase = ''
31 mkdir -p $out/bin
32
33 PSC_PACKAGE=$out/bin/psc-package
34
35 install -D -m555 -T psc-package $PSC_PACKAGE
36 chmod u+w $PSC_PACKAGE
37 '' + lib.optionalString stdenv.isDarwin ''
38 install_name_tool \
39 -change /usr/lib/libSystem.B.dylib ${darwin.Libsystem}/lib/libSystem.B.dylib \
40 -change /usr/lib/libiconv.2.dylib ${libiconv}/libiconv.2.dylib \
41 $PSC_PACKAGE
42 '' + lib.optionalString (!stdenv.isDarwin) ''
43 patchelf --interpreter ${dynamic-linker} --set-rpath ${libPath} $PSC_PACKAGE
44 '' + ''
45 chmod u-w $PSC_PACKAGE
46
47 installShellCompletion --cmd psc-package \
48 --bash <($PSC_PACKAGE --bash-completion-script $PSC_PACKAGE) \
49 --fish <($PSC_PACKAGE --fish-completion-script $PSC_PACKAGE) \
50 --zsh <($PSC_PACKAGE --zsh-completion-script $PSC_PACKAGE)
51 '';
52
53 meta = with lib; {
54 description = "A package manager for PureScript based on package sets";
55 license = licenses.bsd3;
56 maintainers = with maintainers; [ Profpatsch ];
57 platforms = [ "x86_64-darwin" "x86_64-linux" ];
58 };
59}