tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, stdenv, fetchurl, fetchpatch, pkg-config, vala, gobject-introspection, gtk-doc
2, docbook_xsl, docbook_xml_dtd_412, glib, libxml2, libsoup, gnome, buildPackages
3}:
4
5stdenv.mkDerivation rec {
6 pname = "libgrss";
7 version = "0.7.0";
8
9 outputs = [ "out" "dev" "devdoc" ];
10
11 src = fetchurl {
12 url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
13 sha256 = "1nalslgyglvhpva3px06fj6lv5zgfg0qmj0sbxyyl5d963vc02b7";
14 };
15
16 patches = [
17 (fetchpatch {
18 name = "CVE-2016-20011.patch";
19 # https://gitlab.gnome.org/GNOME/libgrss/-/merge_requests/7, not yet merged!
20 url = "https://gitlab.gnome.org/GNOME/libgrss/-/commit/2c6ea642663e2a44efc8583fae7c54b7b98f72b3.patch";
21 sha256 = "1ijvq2jl97vphcvrbrqxvszdmv6yyjfygdca9vyaijpafwyzzb18";
22 })
23 ];
24
25 nativeBuildInputs = [
26 pkg-config
27 vala
28 gobject-introspection
29 gtk-doc
30 docbook_xsl
31 docbook_xml_dtd_412
32 ];
33
34 buildInputs = [
35 glib
36 libxml2
37 libsoup
38 ];
39
40 configureFlags = [
41 "PKG_CONFIG=${buildPackages.pkg-config}/bin/${buildPackages.pkg-config.targetPrefix}pkg-config"
42 ] ++ lib.optionals (stdenv.buildPlatform == stdenv.hostPlatform) [
43 "--enable-gtk-doc"
44 ];
45
46 doCheck = true;
47
48 passthru = {
49 updateScript = gnome.updateScript {
50 packageName = pname;
51 versionPolicy = "none";
52 };
53 };
54
55 meta = with lib; {
56 description = "Glib abstaction to handle feeds in RSS, Atom and other formats";
57 homepage = "https://wiki.gnome.org/Projects/Libgrss";
58 license = licenses.lgpl3Plus;
59 maintainers = teams.gnome.members;
60 platforms = platforms.unix;
61 };
62}