tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, stdenv, fetchFromGitHub, boehmgc, zlib, sqlite, pcre, cmake, pkg-config
2, git, apacheHttpd, apr, aprutil, libmysqlclient, mbedtls, openssl, pkgs, gtk2, libpthreadstubs
3}:
4
5stdenv.mkDerivation rec {
6 pname = "neko";
7 version = "2.3.0";
8
9 src = fetchFromGitHub {
10 owner = "HaxeFoundation";
11 repo = "neko";
12 rev = "v${lib.replaceStrings [ "." ] [ "-" ] version}";
13 sha256 = "19rc59cx7qqhcqlb0znwbnwbg04c1yq6xmvrwm1xi46k3vxa957g";
14 };
15
16 nativeBuildInputs = [ cmake pkg-config git ];
17 buildInputs =
18 [ boehmgc zlib sqlite pcre apacheHttpd apr aprutil
19 libmysqlclient mbedtls openssl libpthreadstubs ]
20 ++ lib.optional stdenv.isLinux gtk2
21 ++ lib.optionals stdenv.isDarwin [ pkgs.darwin.apple_sdk.frameworks.Security
22 pkgs.darwin.apple_sdk.frameworks.Carbon];
23 cmakeFlags = [ "-DRUN_LDCONFIG=OFF" ];
24
25 installCheckPhase = ''
26 bin/neko bin/test.n
27 '';
28
29 doInstallCheck = true;
30 dontPatchELF = true;
31 dontStrip = true;
32
33 meta = with lib; {
34 description = "A high-level dynamically typed programming language";
35 homepage = "https://nekovm.org";
36 license = [
37 # list based on https://github.com/HaxeFoundation/neko/blob/v2-3-0/LICENSE
38 licenses.gpl2Plus # nekoc, nekoml
39 licenses.lgpl21Plus # mysql.ndll
40 licenses.bsd3 # regexp.ndll
41 licenses.zlib # zlib.ndll
42 licenses.asl20 # mod_neko, mod_tora, mbedTLS
43 licenses.mit # overall, other libs
44 "https://github.com/HaxeFoundation/neko/blob/v2-3-0/LICENSE#L24-L40" # boehm gc
45 ];
46 maintainers = [ maintainers.marcweber maintainers.locallycompact ];
47 platforms = platforms.linux ++ platforms.darwin;
48 };
49}