tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, buildGoModule, fetchFromGitHub, llvm, clang-unwrapped, lld, avrgcc
2, avrdude, openocd, gcc-arm-embedded, makeWrapper, fetchurl }:
3
4let main = ./main.go;
5 gomod = ./go.mod;
6in
7buildGoModule rec {
8 pname = "tinygo";
9 version = "0.16.0";
10
11 src = fetchFromGitHub {
12 owner = "tinygo-org";
13 repo = "tinygo";
14 rev = "v${version}";
15 sha256 = "063aszbsnr0myq56kms1slmrfs7m4nmg0zgh2p66lxdsifrfly7j";
16 fetchSubmodules = true;
17 };
18
19 overrideModAttrs = (_: {
20 patches = [];
21 preBuild = ''
22 rm -rf *
23 cp ${main} main.go
24 cp ${gomod} go.mod
25 chmod +w go.mod
26 '';
27 });
28
29 preBuild = "cp ${gomod} go.mod";
30
31 postBuild = "make gen-device";
32
33 vendorSha256 = "12k2gin0v7aqz5543m12yhifc0xsz26qyqra5l4c68xizvzcvkxb";
34
35 doCheck = false;
36
37 prePatch = ''
38 sed -i s/', "-nostdlibinc"'// builder/builtins.go
39 sed -i s/'"-nostdlibinc", '// compileopts/config.go builder/picolibc.go
40 '';
41
42 subPackages = [ "." ];
43 nativeBuildInputs = [ makeWrapper ];
44 buildInputs = [ llvm clang-unwrapped ];
45 propagatedBuildInputs = [ lld avrgcc avrdude openocd gcc-arm-embedded ];
46
47 postInstall = ''
48 mkdir -p $out/share/tinygo
49 cp -a lib src targets $out/share/tinygo
50 wrapProgram $out/bin/tinygo --prefix "TINYGOROOT" : "$out/share/tinygo" \
51 --prefix "PATH" : "$out/libexec/tinygo"
52 mkdir -p $out/libexec/tinygo
53 ln -s ${clang-unwrapped}/bin/clang $out/libexec/tinygo/clang-10
54 ln -s ${lld}/bin/lld $out/libexec/tinygo/ld.lld-10
55 ln -sf $out/bin $out/share/tinygo
56 '';
57
58 meta = with lib; {
59 homepage = "https://tinygo.org/";
60 description = "Go compiler for small places";
61 license = licenses.bsd3;
62 maintainers = with maintainers; [ chiiruno ];
63 };
64}