tjh.dev
1{ lib
2, buildPythonPackage, fetchPypi
3, pkg-config, cython, docutils
4, kivy-garden
5, mesa, mtdev, SDL2, SDL2_image, SDL2_ttf, SDL2_mixer, gst_all_1
6, pillow, requests, pygments
7}:
8
9buildPythonPackage rec {
10 pname = "Kivy";
11 version = "2.0.0";
12
13 src = fetchPypi {
14 inherit pname version;
15 sha256 = "1n0j9046vgjncy50v06r3wcg3q2l37jp8n0cznr64dz48kml8pnj";
16 };
17
18 nativeBuildInputs = [
19 pkg-config
20 cython
21 docutils
22 ];
23
24 buildInputs = [
25 mesa
26 mtdev
27 SDL2
28 SDL2_image
29 SDL2_ttf
30 SDL2_mixer
31
32 # NOTE: The degree to which gstreamer actually works is unclear
33 gst_all_1.gstreamer
34 gst_all_1.gst-plugins-base
35 gst_all_1.gst-plugins-good
36 gst_all_1.gst-plugins-bad
37 ];
38
39 propagatedBuildInputs = [
40 kivy-garden
41 pillow
42 pygments
43 requests
44 ];
45
46 KIVY_NO_CONFIG = 1;
47 KIVY_NO_ARGS = 1;
48 KIVY_NO_FILELOG = 1;
49
50 postPatch = ''
51 substituteInPlace kivy/lib/mtdev.py \
52 --replace "LoadLibrary('libmtdev.so.1')" "LoadLibrary('${mtdev}/lib/libmtdev.so.1')"
53 '';
54
55 /*
56 We cannot run tests as Kivy tries to import itself before being fully
57 installed.
58 */
59 doCheck = false;
60 pythonImportsCheck = [ "kivy" ];
61
62 meta = with lib; {
63 description = "Library for rapid development of hardware-accelerated multitouch applications.";
64 homepage = "https://pypi.python.org/pypi/kivy";
65 license = licenses.mit;
66 maintainers = with maintainers; [ risson ];
67 };
68}