tjh.dev
1{ stdenv
2, fetchurl
3, autoreconfHook
4, docbook_xsl
5, docbook_xml_dtd_43
6, gtk-doc
7, lzip
8, libidn2
9, libunistring
10, libxslt
11, pkgconfig
12, python3
13, valgrind
14, publicsuffix-list
15}:
16
17stdenv.mkDerivation rec {
18 pname = "libpsl";
19 version = "0.21.0";
20
21 src = fetchurl {
22 url = "https://github.com/rockdaboot/${pname}/releases/download/${pname}-${version}/${pname}-${version}.tar.lz";
23 sha256 = "183hadbira0d2zvv8272lspy31dgm9x26z35c61s5axcd5wd9g9i";
24 };
25
26 nativeBuildInputs = [
27 autoreconfHook
28 docbook_xsl
29 docbook_xml_dtd_43
30 gtk-doc
31 lzip
32 pkgconfig
33 python3
34 valgrind
35 ];
36
37 buildInputs = [
38 libidn2
39 libunistring
40 libxslt
41 ];
42
43 propagatedBuildInputs = [
44 publicsuffix-list
45 ];
46
47 postPatch = ''
48 patchShebangs src/psl-make-dafsa
49 '';
50
51 preAutoreconf = ''
52 gtkdocize
53 '';
54
55 configureFlags = [
56 # "--enable-gtk-doc"
57 "--enable-man"
58 "--enable-valgrind-tests"
59 "--with-psl-distfile=${publicsuffix-list}/share/publicsuffix/public_suffix_list.dat"
60 "--with-psl-file=${publicsuffix-list}/share/publicsuffix/public_suffix_list.dat"
61 "--with-psl-testfile=${publicsuffix-list}/share/publicsuffix/test_psl.txt"
62 ];
63
64 enableParallelBuilding = true;
65
66 doCheck = !stdenv.isDarwin;
67
68 meta = with stdenv.lib; {
69 description = "C library for the Publix Suffix List";
70 longDescription = ''
71 libpsl is a C library for the Publix Suffix List (PSL). A "public suffix"
72 is a domain name under which Internet users can directly register own
73 names. Browsers and other web clients can use it to avoid privacy-leaking
74 "supercookies" and "super domain" certificates, for highlighting parts of
75 the domain in a user interface or sorting domain lists by site.
76 '';
77 homepage = "https://rockdaboot.github.io/libpsl/";
78 changelog = "https://raw.githubusercontent.com/rockdaboot/${pname}/${pname}-${version}/NEWS";
79 license = licenses.mit;
80 platforms = platforms.unix;
81 maintainers = [ maintainers.c0bw3b ];
82 };
83}