tjh.dev
1{ stdenv, lib, fetchFromGitHub, autoreconfHook, perl, pkgconfig, flux, zlib
2, libjpeg, freetype, libpng, giflib
3, enableX11 ? true, xorg
4, enableSDL ? true, SDL }:
5
6stdenv.mkDerivation rec {
7 pname = "directfb";
8 version = "1.7.7";
9
10 src = fetchFromGitHub {
11 owner = "deniskropp";
12 repo = "DirectFB";
13 rev = "DIRECTFB_${lib.replaceStrings ["."] ["_"] version}";
14 sha256 = "0bs3yzb7hy3mgydrj8ycg7pllrd2b6j0gxj596inyr7ihssr3i0y";
15 };
16
17 nativeBuildInputs = [ autoreconfHook perl pkgconfig flux ];
18
19 buildInputs = [ zlib libjpeg freetype giflib libpng ]
20 ++ lib.optional enableSDL SDL
21 ++ lib.optionals enableX11 (with xorg; [
22 xorgproto libX11 libXext
23 libXrender
24 ]);
25
26 NIX_LDFLAGS = "-lgcc_s";
27
28 configureFlags = [
29 "--enable-sdl"
30 "--enable-zlib"
31 "--with-gfxdrivers=all"
32 "--enable-devmem"
33 "--enable-fbdev"
34 "--enable-mmx"
35 "--enable-sse"
36 "--with-software"
37 "--with-smooth-scaling"
38 ] ++ lib.optional enableX11 "--enable-x11";
39
40 meta = with lib; {
41 description = "Graphics and input library designed with embedded systems in mind";
42 longDescription = ''
43 DirectFB is a thin library that provides hardware graphics acceleration,
44 input device handling and abstraction, integrated windowing system with
45 support for translucent windows and multiple display layers, not only on
46 top of the Linux Framebuffer Device. It is a complete hardware
47 abstraction layer with software fallbacks for every graphics operation
48 that is not supported by the underlying hardware. DirectFB adds graphical
49 power to embedded systems and sets a new standard for graphics under
50 Linux.
51 '';
52 homepage = "https://github.com/deniskropp/DirectFB";
53 license = licenses.lgpl21;
54 platforms = platforms.linux;
55 maintainers = [ maintainers.bjornfor ];
56 };
57}