tjh.dev
1{ stdenv, python, fetchPypi, makeWrapper, unzip, makeSetupHook
2, pipInstallHook
3, setuptoolsBuildHook
4
5}:
6
7let
8 wheel_source = fetchPypi {
9 pname = "wheel";
10 version = "0.33.6";
11 format = "wheel";
12 sha256 = "f4da1763d3becf2e2cd92a14a7c920f0f00eca30fdde9ea992c836685b9faf28";
13 };
14 setuptools_source = fetchPypi {
15 pname = "setuptools";
16 version = "41.2.0";
17 format = "wheel";
18 sha256 = "4380abcf2a4ffd1a5ba22d687c6d690dce83b2b51c70e9c6d09f7e8c7e8040dc";
19 };
20
21in stdenv.mkDerivation rec {
22 pname = "pip";
23 version = "19.2.3";
24 name = "${python.libPrefix}-bootstrapped-${pname}-${version}";
25
26 src = fetchPypi {
27 inherit pname version;
28 format = "wheel";
29 sha256 = "340a0ba40fdeb16413914c0fcd8e0b4ebb0bf39a900ec80e11c05d836c05103f";
30 };
31
32 dontUseSetuptoolsBuild = true;
33
34 # Should be propagatedNativeBuildInputs
35 propagatedBuildInputs = [
36 # Override to remove dependencies to prevent infinite recursion.
37 (pipInstallHook.override{pip=null;})
38 (setuptoolsBuildHook.override{setuptools=null; wheel=null;})
39 ];
40
41 unpackPhase = ''
42 mkdir -p $out/${python.sitePackages}
43 unzip -d $out/${python.sitePackages} $src
44 unzip -d $out/${python.sitePackages} ${setuptools_source}
45 unzip -d $out/${python.sitePackages} ${wheel_source}
46 '';
47
48 postPatch = ''
49 mkdir -p $out/bin
50 '';
51
52 nativeBuildInputs = [ makeWrapper unzip ];
53 buildInputs = [ python ];
54
55 installPhase = ''
56
57 # install pip binary
58 echo '#!${python.interpreter}' > $out/bin/pip
59 echo 'import sys;from pip._internal import main' >> $out/bin/pip
60 echo 'sys.exit(main())' >> $out/bin/pip
61 chmod +x $out/bin/pip
62
63 # wrap binaries with PYTHONPATH
64 for f in $out/bin/*; do
65 wrapProgram $f --prefix PYTHONPATH ":" $out/${python.sitePackages}/
66 done
67 '';
68
69}