tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ stdenv, src, pkgconfig, tcl, libXft, fontconfig, patches ? [], ... }:
2
3stdenv.mkDerivation {
4 name = "tk-${tcl.version}";
5
6 inherit src patches;
7
8 outputs = [ "out" "man" "dev" ];
9
10 setOutputFlags = false;
11
12 preConfigure = ''
13 configureFlagsArray+=(--mandir=$man/share/man --enable-man-symlinks)
14 cd unix
15 '';
16
17 postInstall = ''
18 ln -s $out/bin/wish* $out/bin/wish
19 cp ../{unix,generic}/*.h $out/include
20 '';
21
22 configureFlags = [
23 "--with-tcl=${tcl}/lib"
24 ];
25
26 nativeBuildInputs = [ pkgconfig ];
27 buildInputs = [ ]
28 ++ stdenv.lib.optional stdenv.isDarwin fontconfig;
29
30 propagatedBuildInputs = [ tcl libXft ];
31
32 NIX_CFLAGS_LINK = if stdenv.isDarwin then "-lfontconfig" else null;
33
34 doCheck = false; # fails. can't find itself
35
36 inherit tcl;
37
38 passthru = rec {
39 inherit (tcl) release version;
40 libPrefix = "tk${tcl.release}";
41 libdir = "lib/${libPrefix}";
42 };
43
44 meta = with stdenv.lib; {
45 description = "A widget toolkit that provides a library of basic elements for building a GUI in many different programming languages";
46 homepage = http://www.tcl.tk/;
47 license = licenses.tcltk;
48 platforms = platforms.all;
49 maintainers = with maintainers; [ lovek323 vrthra ];
50 };
51}