tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ stdenv, lib, fetchFromGitHub, autoreconfHook, pkgconfig
2, libXext, libdrm, libXfixes, wayland, libffi, libX11
3, libGL, libGL_driver
4, minimal ? false, libva-minimal
5}:
6
7stdenv.mkDerivation rec {
8 name = "libva-${lib.optionalString minimal "minimal-"}${version}";
9 version = "2.4.0";
10
11 # update libva-utils and vaapiIntel as well
12 src = fetchFromGitHub {
13 owner = "01org";
14 repo = "libva";
15 rev = version;
16 sha256 = "1b58n6rjfsfjfw1s5kdfa0jpfiqs83g2w14s7sfp1qkckkz3988l";
17 };
18
19 outputs = [ "dev" "out" ];
20
21 nativeBuildInputs = [ autoreconfHook pkgconfig ];
22
23 buildInputs = [ libdrm ]
24 ++ lib.optionals (!minimal) [ libva-minimal libX11 libXext libXfixes wayland libffi libGL ];
25 # TODO: share libs between minimal and !minimal - perhaps just symlink them
26
27 enableParallelBuilding = true;
28
29 configureFlags = [
30 # Add FHS paths for non-NixOS applications.
31 "--with-drivers-path=${libGL_driver.driverLink}/lib/dri:/usr/lib/dri:/usr/lib32/dri"
32 ] ++ lib.optionals (!minimal) [ "--enable-glx" ];
33
34 installFlags = [
35 "dummy_drv_video_ladir=$(out)/lib/dri"
36 ];
37
38 meta = with stdenv.lib; {
39 description = "VAAPI library: Video Acceleration API";
40 homepage = http://www.freedesktop.org/wiki/Software/vaapi;
41 license = licenses.mit;
42 maintainers = with maintainers; [ garbas ];
43 platforms = platforms.unix;
44 };
45}