tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ stdenv, fetchFromGitHub, cmake, python }:
2# Like many google projects, shaderc doesn't gracefully support separately compiled dependencies, so we can't easily use
3# the versions of glslang and spirv-tools used by vulkan-loader. Exact revisions are taken from
4# https://github.com/google/shaderc/blob/known-good/known_good.json
5
6# Future work: extract and fetch all revisions automatically based on a revision of shaderc's known-good branch.
7let
8 glslang = fetchFromGitHub {
9 owner = "KhronosGroup";
10 repo = "glslang";
11 rev = "712cd6618df2c77e126d68042ad7a81a69ee4a6f";
12 sha256 = "0wncdj6q1hn40lc7cnz97mx5qjvb8p13mhxilnncgcmf0crsvblz";
13 };
14 spirv-tools = fetchFromGitHub {
15 owner = "KhronosGroup";
16 repo = "SPIRV-Tools";
17 rev = "df5bd2d05ac1fd3ec3024439f885ec21cc949b22";
18 sha256 = "0l8ds4nn2qcfi8535ai8891i3547x35hscs2jxwwq6qjgw1sgkax";
19 };
20 spirv-headers = fetchFromGitHub {
21 owner = "KhronosGroup";
22 repo = "SPIRV-Headers";
23 rev = "79b6681aadcb53c27d1052e5f8a0e82a981dbf2f";
24 sha256 = "0flng2rdmc4ndq3j71h6wk1ibcjvhjrg2rzd6rv445vcsf0jh2pj";
25 };
26in stdenv.mkDerivation rec {
27 name = "shaderc-${version}";
28 version = "2018.0";
29
30 outputs = [ "out" "lib" "bin" "dev" "static" ];
31
32 src = fetchFromGitHub {
33 owner = "google";
34 repo = "shaderc";
35 rev = "v${version}";
36 sha256 = "0qigmj0riw43pgjn5f6kpvk72fajssz1lc2aiqib5qvmj9rqq3hl";
37 };
38
39 patchPhase = ''
40 cp -r --no-preserve=mode ${glslang} third_party/glslang
41 cp -r --no-preserve=mode ${spirv-tools} third_party/spirv-tools
42 ln -s ${spirv-headers} third_party/spirv-tools/external/spirv-headers
43 '';
44
45 nativeBuildInputs = [ cmake python ];
46
47 postInstall = ''
48 moveToOutput "lib/*.a" $static
49 '';
50
51 preConfigure = ''cmakeFlags="$cmakeFlags -DCMAKE_INSTALL_BINDIR=$bin/bin"'';
52
53 enableParallelBuilding = true;
54
55 cmakeFlags = [ "-DSHADERC_SKIP_TESTS=ON" ];
56
57 meta = with stdenv.lib; {
58 inherit (src.meta) homepage;
59 description = "A collection of tools, libraries and tests for shader compilation.";
60 license = [ licenses.asl20 ];
61 };
62}