tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ fetchgit, pkgconfig, gettext, runCommand, makeWrapper
2, elfutils, kernel, gnumake, python2, pythonPackages, binutils }:
3let
4 ## fetchgit info
5 url = git://sourceware.org/git/systemtap.git;
6 rev = "276ed27a3cc64531542ab73bb36bb04784e79bbc";
7 sha256 = "11967dx3cjs96v3ncfljw0h7blsgg9wm8g9z2270q9a90988g2c2";
8 version = "2017-02-04";
9
10 inherit (kernel) stdenv;
11 inherit (stdenv) lib;
12
13 ## stap binaries
14 stapBuild = stdenv.mkDerivation {
15 name = "systemtap-${version}";
16 src = fetchgit { inherit url rev sha256; };
17 buildInputs = [ elfutils pkgconfig gettext python2 pythonPackages.setuptools ];
18 # FIXME: Workaround for bug in kbuild, where quoted -I"/foo" flags would get mangled in out-of-tree kbuild dirs
19 postPatch = ''
20 substituteInPlace buildrun.cxx --replace \
21 'o << "EXTRA_CFLAGS += -I\"" << s.runtime_path << "\"" << endl;' \
22 'o << "EXTRA_CFLAGS += -I" << s.runtime_path << endl;'
23 '';
24 enableParallelBuilding = true;
25 };
26
27 ## a kernel build dir as expected by systemtap
28 kernelBuildDir = runCommand "kbuild-${kernel.version}-merged" { } ''
29 mkdir -p $out
30 for f in \
31 ${kernel}/System.map \
32 ${kernel.dev}/vmlinux \
33 ${kernel.dev}/lib/modules/${kernel.modDirVersion}/build/{*,.*}
34 do
35 ln -s $(readlink -f $f) $out
36 done
37 '';
38
39in runCommand "systemtap-${kernel.version}-${version}" {
40 inherit stapBuild kernelBuildDir;
41 buildInputs = [ makeWrapper ];
42 meta = {
43 homepage = https://sourceware.org/systemtap/;
44 repositories.git = url;
45 description = "Provides a scripting language for instrumentation on a live kernel plus user-space";
46 license = lib.licenses.gpl2;
47 platforms = lib.platforms.linux;
48 };
49} ''
50 mkdir -p $out/bin
51 for bin in $stapBuild/bin/*; do # hello emacs */
52 ln -s $bin $out/bin
53 done
54 rm $out/bin/stap
55 makeWrapper $stapBuild/bin/stap $out/bin/stap \
56 --add-flags "-r $kernelBuildDir" \
57 --prefix PATH : ${lib.makeBinPath [ stdenv.cc.cc binutils elfutils gnumake ]}
58''